Dear Monks,

As I was thinking about this node about dynamically building regexes, I had the idle thought that it might be nice if qr// supported qr//e, analogous to s///e it would eval the inside of the construct before parsing it as a regex. Now this is really just a very minor itch, and I don't yet have any idea of how much sense it makes or how difficult it might be to implement, but I still thought I'd bounce it off of you.

Thoughts? Maybe the "normal" and/or "hacked" solutions below are good enough, and the effort required to implement qr//e isn't worth it? Other potential problems I haven't noticed yet?

Update 2017-01-19: TIMTOWTDI has already provided plenty of possible solutions, and I just wasn't feeling creative enough at the moment to see them :-) Thank you very much, LanX, Haarg, and vr! I updated the code with your solutions, and added Test::More and sub testre.

Code:

use warnings;
use strict;
use Test::More;
sub testre;

# The "normal" solution
my $re = join '|', map {quotemeta} qw/a . | %/;
testre  qr/$re/i ;

# The "hacked" solution
testre  qr{@{[ join '|', map {quotemeta} qw/a . | %/ ]}}i ;

# Wouldn't this be a bit nicer?
#testre  qr{ join '|', map {quotemeta} qw/a . | %/ }ei ;

# ### Update ###

# Thanks to LanX
sub qre (&;$) {
    my $re = shift->();
    eval 'qr/$re/'.(shift//'') || die $@
}
testre  qre{ join '|', map {quotemeta} qw/a . | %/ }'i' ;

# Thanks to Haarg
testre  map qr/$_/i, join '|', map {quotemeta} qw/a . | %/ ;

# Thanks to vr
testre  qr{(??{ join '|', map {quotemeta} qw/a . | %/ })}i ;

done_testing;

sub testre {
    my $re = shift;
    diag explain $re;
    is ref $re, 'Regexp';
    like $_, $re for qw/A . | %/;
    unlike 'bcd', $re;
}
[download]

Regards,
-- Hauke D

Update almost 6 months later: I just happened to stumble across this node: qr// with /e? :-)