Using HTML::TreeBuilder to change the DOCTYPE declaration

wfsp has asked for the wisdom of the Perl Monks concerning the following question:

The look_down method is not finding the DOCTYPE declaration although it is present in Data::Dumpers output as described in the docs. What's the best way to do this?

#!/usr/bin/perl
use warnings;
use strict;
use Data::Dumper;
$Data::Dumper::Indent = 1;
$Data::Dumper::Sortkeys = 1;

use HTML::TreeBuilder;

my $content = do{local $/;<DATA>};
my $root = HTML::TreeBuilder->new_from_content($content);

print $root->tag, qq{\n}; 
# prints: html
print $root->{_decl}{_tag}, qq{\n}; 
# prints: ~declaration
print $root->{_decl}{text}, qq{\n}; 
# prints: DOCTYPE html PUBLIC "XHTML"

my $dec = $root->look_down(
  _tag  => q{~declaration},
) or die qq{declaration not found\n};


$dec->splice_content(
  0, 
  1, 
  q{<!DOCTYPE html PUBLIC "HTML4">},
) or die qq{splice failed\n};

print $root->as_HTML;

__DATA__
<!DOCTYPE html PUBLIC "XHTML">
<html>
<head><title>declaration</title></head>
<body><p>declaration</p></body>
</html>
[download]

extract from Data::Dumper output

  '_decl' => bless( {
    '_tag' => '~declaration',
    'text' => 'DOCTYPE html PUBLIC "XHTML"'
  }, 'HTML::Element' ),
[download]

Comment on Using HTML::TreeBuilder to change the DOCTYPE declaration Select or Download Code

Replies are listed 'Best First'.

Re: Using HTML::TreeBuilder to change the DOCTYPE declaration
by ikegami (Patriarch) on Nov 04, 2008 at 11:20 UTC

The doctype is stored as an attribute of the root element where the attribute name is "_decl" and the value is an HTML::Element object, so basically, you want

my $ele = $root->look_down(
   _decl => ...was specified...,
) or die qq{declaration not found\n};

my $dec = $ele->attr('_decl');
[download]

Since look_down doesn't allow us to check if an attribute was specified we'll have to provide our own handler.

my $ele = $root->look_down(
   sub { $_[0]->attr('_decl') }
) or die qq{declaration not found\n};

my $dec = $ele->attr('_decl');
[download]

But why use look_down at all? The only possible node it could return is the root node. The above code boils down to

my $dec = $root->attr('_decl')
   or die qq{declaration not found\n};
[download]

Now that we have the declaration, let's move on to changing it. It makes no sense to use splice_content to modify attributes. attr is the proper method.

$dec->attr(text => 'DOCTYPE html PUBLIC "HTML4"');
[download]

Since the entire purpose is to replace the declaration, let's create a new declaration rather than dying if it's absent.

$root->attr('_decl',
   HTML::Element->new('~declaration',
      text => 'DOCTYPE html PUBLIC "HTML4"',
   )
);
[download]

All together:

#!/usr/bin/perl

use warnings;
use strict;

use HTML::TreeBuilder;

my $content = do{local $/;<DATA>};
my $root = HTML::TreeBuilder->new_from_content($content);

$root->attr('_decl',
   HTML::Element->new('~declaration',
      text => 'DOCTYPE html PUBLIC "HTML4"',
   )
);

print $root->as_HTML;

__DATA__
<!DOCTYPE html PUBLIC "XHTML">
<html>
<head><title>declaration</title></head>
<body><p>declaration</p></body>
</html>
[download]

<!DOCTYPE html PUBLIC "HTML4">
<html><head><title>declaration</title></head><body><p>declaration</bod
+y></html>
[download]

[reply]
[d/l]
[select]


Your skill will accomplish what the force of many cannot
	PerlMonks