You could go (almost) without regexes and just get the pairs yourself - at the cost of some memory (since you need to store all the separate words):

#!/usr/local/bin/perl -w
use strict;
my $s = 'This is a test';

my @words = split / +/,$s;

my @pairs = map [@words[$_,$_+1]],0 .. @words-2;
[download]

Depends what you call better:

use strict;
use warnings;

my $s = 'This is a test';
my @pairs = $s =~ /(?=(\w+ \s+ \w+))\w+ \s+/gx;

print join "\n", @pairs;
[download]

Prints:

This is
is a
a test
[download]

Update: or if you want @pairs as an AoA:

...
my @pairs = map [split], $s =~ /(?=(\w+ \s+ \w+))\w+ \s+/gx;

print "@$_\n" for @pairs;
[download]

prints:

This is
is a
a test
[download]

$_ = 'This is a test';
my @words = split;
my @wordpairs = map {[ $words[$_-1], $words[$_] ]} 1..$#words;
[download]

Update: oops! I failed to notice that Joost already provided this solution. (I should have expected that he would.) Apologies for being redundant.

For my cryptography hobby (old school cryptograms, not modern cypto), I wrote this to find frequencies of letter pairs. I don't know if it could be adapted.

# 
# 
# my $input = shift;
# my $input = "peon bookkeeper";
my $input;
#print $input."\n";
while (<>) {
    $input = $_;
    @evenmatches = ($input =~ m/
                                (.{2}?)
                                (?{ #print $^N . " found at " . ($tmpp
+os = pos($input)) . "\n";
                                    $chars{$^N}++; 
                                  })
                               /xg);
    #print join(", ", @evenmatches)."\n";
    #print $#evenmatches + 1 ." matches found\n";
    
    #print $input."\n";
    pos($input) = 1;
    @oddmatches = ($input =~ m/
                                (.{2}?)
                                (?{ #print $^N . " found at " . ($tmpp
+os = pos($input)) . "\n";
                                    $chars{$^N}++; 
                                  })
                               /xg);
    #print join(", ", @oddmatches)."\n";
    #print $#oddmatches + 1 ." matches found\n";
}

print "frequency of '$_' is $chars{$_}\n"
    foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
print "\n";    
print "frequency of '$_' is $chars{$_}\n"
    foreach (sort keys %chars);
[download]