Re: -pi -e argv repeater

Perhaps you'd like

use constant PIE_NO_BACKUP => '';

sub pie(&$@) {
   (
      my $code,     # Code ref
      local $^I,    # PIE_NO_BACKUP, '~', '.bak', etc
      local @ARGV,
   ) = @_;

   local *_;     # Protect caller's $_.
   while (<>) {
      chomp;
      $code->();
      print($_, "\n");
   }
}

# perl -i -pe 's///' file1 file2
pie { s/// } PIE_NO_BACKUP, 'file1', 'file2';

# perl -i.bak -pe 's///' file? data*.txt
pie { s/// } '.bak', map { bsd_glob($_) } 'file?', 'data*.txt';
[download]

Untested.

Update: Added missing "\n". Created constant for no backup. Added local *_;.

Comment on Re: -pi -e argv repeater Select or Download Code

Replies are listed 'Best First'.
Re^2: -pi -e argv repeater by jettero (Monsignor) on Feb 02, 2007 at 15:57 UTC
$^I is apparently all I needed. I had no idea it would be so simple, thanks. I obviously should have just asked on the chatterbox... how embarassing. -Paul	[reply]
Re^2: -pi -e argv repeater by OfficeLinebacker (Chaplain) on Feb 03, 2007 at 19:08 UTC
May I ask what the (&$@) in the sub declaration is for? I like computer programming because it's like Legos for the mind.	[reply]
Re^3: -pi -e argv repeater by ikegami (Patriarch) on Feb 03, 2007 at 19:14 UTC
It's a prototype. Without the prototype, you'd have to do `pie sub { CODE }, SCALAR, LIST` or `pie &func, SCALAR, LIST` With the prototype, you can also do `pie { CODE } SCALAR, LIST`	[reply] [d/l] [select]
Re^4: -pi -e argv repeater by OfficeLinebacker (Chaplain) on Feb 04, 2007 at 17:13 UTC
Ikegami, I see you disagree with Damian Conway (as expressed in Perl Best Practices--pp 194-196 for those of you following from home). I wish I understood better the exact thought processes behind each of your approaches. Either way, yes, $^I is the way to go (or, if you really want to be a Boy Scout about it, use English, only without the evil regexp vars, and use $INPLACE_EDIT in place of $^I). I like computer programming because it's like Legos for the mind.	[reply]
Re^5: -pi -e argv repeater by BrowserUk (Patriarch) on Feb 04, 2007 at 19:13 UTC
Re^5: -pi -e argv repeater by ikegami (Patriarch) on Feb 04, 2007 at 20:09 UTC
Re^5: -pi -e argv repeater by OfficeLinebacker (Chaplain) on Feb 04, 2007 at 23:20 UTC
Re^6: -pi -e argv repeater by ikegami (Patriarch) on Feb 05, 2007 at 01:25 UTC
Re^6: -pi -e argv repeater by BrowserUk (Patriarch) on Feb 05, 2007 at 00:29 UTC
Some notes below your chosen depth have not been shown here


Problems? Is your data what you think it is?
	PerlMonks