A couple of FAQs that you might find useful:

• How do I compute the difference of two arrays? How do I compute the intersection of two arrays?
• How do I test whether two arrays or hashes are equal?

Hi tsk1979 ,

There is a module List::Compare will do that work.

use strict;
use warnings;
use List::Compare;

my @a = qw(-true -depth=1);
my @b = qw(-search -depth=1 -true -expand_all) ;

 

my $lc = List::Compare->new( \@a, \@b );

my @a_only = $lc->get_Lonly;
my @b_only = $lc->get_Ronly;

print join( ', ', @a_only ), "\n"; # 1, 2

@a_only ? print "@a_only" : print "\nAll Matched";
[download]

Hi tsk1979, Try this,

 use strict;
 use warnings;
 use Array::Compare;
 
 my @ar1 = qw(-true -depth=1); 
 my @ar2 = qw(-search -depth=1 -true -expand_all);
 my $comp = Array::Compare->new();
 if ($comp->compare(\@ar1, \@ar2)){print "Same Array OK";}else{print "
+Different Array OK";}
[download]

Updated davorg solution is correct. compare function compare the arrays in order.

Looks like order isn't significant, so you might be better off using the perm method rather than the compare method.

--
<http://dave.org.uk>

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

Using a temporary hash and List::MoreUtils:

use List::MoreUtils qw(all);

use strict;
use warnings;

my @partial = qw(-true -depth=1);
my @complete = qw (-search -depth=1 -true -expand_all);

my %temp;
@temp{@complete} = @complete;

print "Yep\n" if all { exists $temp{$_} } @partial;
[download]

I don't think you need the module. Remember that all positive is the same as none negative.

my %temp;
@temp{@complete} = @complete;

print "Yep\n" unless grep { ! exists $temp{$_} } @partial;
[download]

We're building the house of the future together.

The %temp hash doesn't need to have the data from the @complete in both keys and values. Especially since you already use exists().

my %temp;
@temp{@complete} = ();
[download]

ie enough.

Jenda


Support Denmark! Defend the free world!

use strict;
use warnings;

my @a = qw(-true -depth=1);
my @b = qw(-search -depth=1 -true -expand_all);

print '@b contains @a' if @a == grep defined, @{{map {$_=>$_} @b}}{@a}
+;
[download]

O. K., I'm not too serious about proposing this. Though it meets my sense of elegance (somehow).

Also note that no counting takes place: If an element appears more than once in @a they will be covered by a single (identical) entry in @b for acknowledging their containment.

use Quantum::Superpositions;
@a = qw(-true -depth=1);
@b = qw(-search -depth=1 -true -expand_all...);
@c = qw(-true -depth=1 -height);

print "right" unless eigenstates(any(@a) ne all(@b));
print "wrong" unless eigenstates(any(@c) ne all(@b));
[download]

right
[download]