I have a box of a dozen doughnuts. I want to eat three of them, and still have a full box with a dozen when I'm done.

Solution? You need another box. ;)

In Perl, you need two arrays; one is the original, and one will be the copy, on which you can perform whatever manipulations you wish, without affecting the original.

my @array = qw/one two three four five/;
my @copy  = @array;

shift @copy;

print "Original: @array\n";
print "Copy:     @copy\n";
[download]

There are infinite other strategies, but your question is vague enough to make it impossible to focus on which strategy would be optimal.

You want grep (to remove rows), map (to transform rows) or List::MoreUtils's apply (to transform rows).

When using grep or map, don't change $_ unless you want to change the original array.

apply is similar to map, but you can safely modify $_. The downside to using apply is that you're limited to 1:1 transformations (whereas map is extremely flexible).

use List::MoreUtils qw( apply );

my @orig    = qw( Just another Perl hacker );
my @grepped = grep  { /^[A-Z]/      } @orig;
my @mapped  = map   { uc            } @orig;
my @applied = apply { s/[aiueo]//ig } @orig;

print("@orig\n");     # Just another Perl hacker
print("@grepped\n");  # Just Perl
print("@mapped\n");   # JUST ANOTHER PERL HACKER
print("@applied\n");  # Jst nthr Prl hckr
[download]

List::MoreUtils can easily be installed if you're using ActivePerl. Just type by ppm install List-MoreUtils at the prompt

my @source = (1,2,3,4);
my @dest = map { $_ * 2 } @source;
print "@source\n";
print "@dest\n";

#Output:
#1 2 3 4
#2 4 6 8
[download]

my @source = ('bob', 'joe');
my @dest = map { $_ eq 'bob' ? ucfirst($_) : $_ } @source;
print "@source\n";
print "@dest\n";
#Output:
#bob joe
#Bob joe
[download]

@a=("sedam","medam","kadam","sadam");
for(@b=@a)
{
  s/dam/lam/;
}
print "@b\n";
print "@a";
[download]

#!/usr/bin/perl -w
@a=("sedam","medam","kadam","sadam");
for(@b=@a)
{
  s/dam/lam/;
}
print "@b\n";
print "@a";
[download]

@new = map { ... } @{[ @original ]};
[download]

@new = grep { local $_ = $_; ... } @original;
[download]

... for @new = @original;
[download]

do { ...; ... } for @new = @original;
[download]