$board =~ /(?<!\w).{2,}(?!\w)(?{ push @pat, [ $-[0], $& ] })(*FAIL)/
+;
[download]

This is the heart of finding a place to move. For a word to be a legal move, it must match one of the patterns in @pat. The (?<!\w) prevents putting the new word next to a preceding word, and the (?!\w) prevent putting the new word abutting a following word. The(*FAIL) forces the regex engine to try every possible place to find a match.

Try

perl -le ' "abcd" =~ /.{2,}(?{print $&})(*FAIL)/ '
[download]

and notice it prints out every substring with two or more characters.

leaving vertical space for respondents...

Read more... (9 kB)

Thanks for your comment,

Explanation of the masking in "matchrule"



sub matchrule {
  my ( $old, $highs, $word ) = @_;
  $old eq $word and return 0;
  my $newmask = ( $old ^ $word ) =~ tr/\0/\xff/cr;
  ( $newmask & $highs ) =~ tr/5// and return 0;
  my $tiles = "@tiles";
  $tiles =~ s/$_// or return 0 for ( $newmask & $word ) =~ /\w/g;
  return 1;
}
[download]

Let's follow a call to matchrule('hello', '14222', 'world')

First off, if old and word are the same, it's not a valid move.

Next, get the mask. ( note: strings have been printed by Data::Dumper::Useqq = 1 )

'hello' ^ 'world' => "\37\n\36\0\13"
[download]

However, I want to change all non nulls ("\0") to "\xff" so that characters can pass through these positions unchanged.

my $newmask = ('hello' ^ 'world') =~ tr/\0/\xff/cr => "\377\377\377\0\
+377"
[download]

Now we use this mask against the tile heights and look for any 5's, because the "\xff" in $newmask are at the positions where new tiles will be added.

("\377\377\377\0\377" & '14222') => "142\0002"
[download]

and since there is no 5, the new word is not invalid (yet).

"\377\377\377\0\377" & 'world' => "wor\0d"
[download]

This leaves only the new tiles that must be played, ignoring the "\0" because those positions use the old tile. So remove each new letter from a string of the tile rack, and if any are not there, the move is invalid.

Hope this helps.

    my $newmask = ( $old ^ $word ) =~ tr/\0/\xff/cr;
    $flip and ( $board, $heights ) = flip $board, $heights;
    substr $board, $pos, length $word, $word;

    #say "new mask is $newmask";
    substr $heights, $pos, length $highs,
      ( $highs & $newmask ) =~ tr/0-4/1-5/r | ( $highs & ~$newmask );
    $flip and ( $board, $heights ) = flip $board, $heights;
    my $tiles = join '', @tiles;
    say "word is $word";
    $tiles =~ s/$_// for split //, $word & $newmask;
[download]

let me try...

    my $newmask = ( $old ^ $word ) =~ tr/\0/\xff/cr;
[download]

$newmask is "\xff" where the old and new words differ, that is a new tile must be used. It is "\0" where no tile is to be placed (using existing board state).

    $flip and ( $board, $heights ) = flip $board, $heights;
    substr $board, $pos, length $word, $word;

    #say "new mask is $newmask"; # $newmask has unprintable characters
+, use something like Data::Dump that will show them.
    substr $heights, $pos, length $highs,
      ( $highs & $newmask ) =~ tr/0-4/1-5/r | ( $highs & ~$newmask );
[download]

hehehe! GOAL => increment the stack sizes for only the new tiles.

$highs & $newmask produces a string that only has non-null characters where new tiles are to be played. In other words, it isolates the stacks for the new tiles, everywhere else is "\0".
=~ tr/0-4/1-5/r increments the height for each place a new tile is played.
~$newmask inverts $newmask to be "\xff" only where old tiles remain visible.
$highs & ~$newmask produces a string with only the unchanged stack values (and "\0" where the new values are).
Finally, the | puts the old and new stack counts together so they can be replaced in the heights string.

    $flip and ( $board, $heights ) = flip $board, $heights;
    my $tiles = join '', @tiles;
    say "word is $word";
    $tiles =~ s/$_// for split //, $word & $newmask;
[download]

This removes the tiles that are used for this word from the string of all tiles, soon to be replaced in @tiles.

Hope this helps...