This is PerlMonks "Mobile"

Beefy Boxes and Bandwidth Generously Provided by pair Networks
go ahead... be a heretic
 
PerlMonks  

I was recently faced with a thread that used .= on a shared variable, and I wondered if that was safe. I figured I'd write up a introductory tutorial on the answer I found. For simplicity, we'll look at ++ first.

The following code outputs 400,000: 

my $count     = 100_000;
my $num_calls = 4;

my $sum = 0;
sub inc { ++$sum for 1..$count; }

inc() for 1..$num_calls;
print("$sum\n");   # 400000

[download]

If you ran the 4 calls to inc in parallel, would the answer still be 400,000? Not likely, if you don't change inc. 

use threads;
use threads::shared;

my $count     = 100_000;
my $num_calls = 4;

my $sum : shared = 0;
sub inc { ++$sum for 1..$count; }

$_->join for map { threads->create( \&inc ) } 1..$num_calls;
print("$sum\n");   # 314813

[download]

That's because there is a race condition. 

+=======================+
|          CPU          |
+-----------+-----------+
| thread 1  | thread 2  |
+===========+===========+
| ...       |           |   T
| load $sum |           |   i
| inc       |           |   m
+-----------+-----------+   e
|           | ...       |   |
|           | load $sum |   |
|           | inc       |   v
|           | save $sum |
|           | ...       |
+-----------+-----------+
| save $sum |           |
| ...       |           |
+===========+===========+

[download]

The solution is to protect the critical section using a thread synchronization mechanism such as lock. 

use threads;
use threads::shared;

my $count     = 100_000;
my $num_calls = 4;

my $sum : shared = 0;
sub inc { for (1..$count) { lock($sum); ++$sum } }

$_->join for map { threads->create( \&inc ) } 1..$num_calls;
print("$sum\n");   # 400000

[download]

Whenever an transformation operation (read ⇒ manipulate ⇒ write) is performed on a shared variable, locking is needed. See threads::shared for tools to do this.

The program behind the <spoiler> below outputs results similar to the following: 

++s     sum = 233564 (expecting 400000)
s+=1    sum = 143915 (expecting 400000)
c.=l    length = 248149 (expecting 400000)
c=c.l   length = 123360 (expecting 400000)

[download]

As you can see, +=, .= and = . are also not atomic. The program can only prove that an operator isn't atomic (i.e. is interruptable). It cannot prove that an operator is atomic (i.e. is not interruptable). If you're getting the "expecting" result, try upping $count and/or $threads.

<Reveal this spoiler or all in this thread>

Update: Added the preface and links to Wikipedia.

Added to Tutorials by planetscape

( keep:0 edit:6 reap:0 )

Replies are listed 'Best First'.
Re: Threads: why locking is required when using shared variables
by monarch (Priest) on Oct 20, 2006 at 13:58 UTC
    This is a great introduction and, certainly, locking of shared variables is essential learning and understanding for anyone who is going to be using threads.

    Perhaps it is worth mentioning, in this particular case, that the lock function doesn't need an explicit unlock. Rather, a locked variable becomes unlocked when the code execution exits the current scope.

[reply]
[d/l]
[select]

      That reminds me of a very useful bit of information reguarding locking. A single lock variable can be used to control access to multiple shared variables. For example, 

      my $list_head : shared;   # Access controlled by $list_head.
my $list_tail : shared;   # Access controlled by $list_head.

sub ... {
   ...
   {
      lock($list_head);
      ... code that uses $list_head and/or $list_tail ...
   }
   ...
}

      [download]

      It doesn't matter which variable is used as to control access to a give shared variable, as long as you *always* use the same lock variable to control access to that shared variable.

[reply]
[d/l]

Back to Tutorials