in other word, the full source code

• spell
• XML

rdfield

This sounds like a perfect use for a SAX filter.

Process your file and event at a time. When you get a text event, run it through your spell checker. Write either the original event or the corrected text into a new file.

"The first rule of Perl club is you do not talk about Perl club."
-- Chip Salzenberg

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)

What if your XML is a document, that will be later converted to HTML, PDF an text? Then it makes sense to spell-check it the XML instead of one of the target formats. Granted your XML editor probably has a spell checker already, but if you use a pure text editor that has no spell checking capability (ed? ;--) to create short XML documents, or if you receive them from other authors that do not spell check them, then it might make sense to spell check the XML as a separate step.

You might want to look at the handy dandy XML::Simple module. Look at the XMLin() and XMLout() methods. XMLin() allows you to read in an XML document. Loop through the data structure that is returned from XMLin(), run your spell check on the data within in, then write the final results back to the XML document via XMLout().

      C:\>shutdown -s
      >> Could not shut down computer:
      >> Microsoft is logged in remotely.
    

XML::Simple would probably not work here as it is designed for data-oriented XML and would not properly handle XML documents that include <p>some <i>mixed content</i> like this</p>.

As for this method being a problem for very large files, in that case the bottleneck would not be the processing time but more likely the time spent using the spell checker interractively. If that's really a problem (a huge file with very few spelling mistakes) you can always do it chunk by chunk using... say... XML::Twig ;--)

eg:

1. spell error on "tex"
 
   <xmltag>tex</xmltag>.

2. extract tex to one file to do spell checking.
   extract <xmltag> to other file.

   content of file 1:         tex 
   content of file 2: <xmltag>   </xmltag> 

3. check the content of file 1 :  tex --> text

4. after spell checking

   content of file 1:         text
   content of file 2: <xmltag>   </xmltag>

5. combine the content of this two file
   -produce new xml file that contain:

       <xmltag>text</xmltag>
[download]

Well, i finally convinced myself that i have already written something very similar to this: (jeffa) Re: XML Search and Replace. That combined with my Lingua::Ispell review yielded the following:

use strict;
use warnings;

use XML::Parser;
use XML::Writer;
use Lingua::Ispell qw(spellcheck);

# change me to the output of 'which ispell'
$Lingua::Ispell::path = '/path/to/ispell';

my $writer = XML::Writer->new();
my $parser = XML::Parser->new(
   Handlers => {
      Init  => \&handle_Init,
      Start => \&handle_Start,
      Char  => \&handle_Char,
      End   => \&handle_End,
      Final => \&handle_Final,
   }
);
$parser->parse(*DATA);

sub handle_Init {
   $writer->xmlDecl('UTF-8');
   $writer->doctype('xml');
}

sub handle_Start {
   my($self,$name,%atts) = @_;
   $writer->startTag($name,%atts);
}

sub handle_Char {
   my($self,$text) = @_;
   for my $r (spellcheck($text)) {
      if ($r->{type} eq 'miss') {
         $text =~ s/$r->{term}/$r->{misses}->[0]/;
      }
   }
   $writer->characters($text);
}

sub handle_End {
   my($self,$name) = @_;
   $writer->endTag($name);
}

sub handle_Final {
   $writer->end();
}

__DATA__
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xml>
<xml>
  <stuff class="spelled wrong">
    <item>ys we ave no banans</item>
    <item>els in my hooverkraft</item>
  </stuff>
  <stuff class="spelled right">
    <item>yes we have no bananas</item>
    <item>eels in my hovercraft</item>
  </stuff>
</xml>
[download]

The important part is the handle_Char() subroutine. Right now, it simply replaces the mispelled item with the first 'miss' ispell coughs up. You will need to add an interface that allows a user to choose which miss they really want. That should be fairly simple - print the list of misses out for the user along with each misses' index to $r->{misses} and have them enter the index number. Also note that my script uses the built-in DATA filehandle for input and stdout for output -- you will want to change these. Good luck, and remember that this is Just One Way To Do It -- there are many more. :)

jeffa

L-LL-L--L-LL-L--L-LL-L--
-R--R-RR-R--R-RR-R--R-RR
B--B--B--B--B--B--B--B--
H---H---H---H---H---H---
(the triplet paradiddle with high-hat)