http://qs321.pair.com?node_id=1230171


in reply to Re^7: How can I read DATA in parent and child?
in thread How can I read DATA in parent and child?

Your race condition is: one side of fork gets to the (buffered) read before the other side gets to its seek().

I find it easier to see what is going on by using non buffered reads (sysread). Half-offsetting (timewise) the two forks leads to consistent results.

Removing the (unnecessary) seeks()'s should also lead to consistent output size (although it could be from either the parent or child). 

#!/usr/bin/perl

# https://perlmonks.org/?node_id=1230099

use strict;
use warnings;
use IO::Handle;
$| = 1;

my $pos = tell DATA;
my $pid = fork();

my $x= IO::Handle->new();
$x->fdopen(fileno(DATA), "r");

$pid and select undef, undef, undef, 0.05;
seek $x, $pos, 0;

while( sysread $x, $_, 1 )
  {
  print $pid ? uc : lc;
  select undef, undef, undef, 0.1;
  }

1 while wait > 0;

__DATA__
aa
bb
cc
dd
ee

[download]

Outputs: 

aAa
bB
Cc
dD
Ee

[download]

Note the extra 'a' as a result of the seek().

Replies are listed 'Best First'.
Re^9: How can I read DATA in parent and child?
by Skeeve (Parson) on Feb 20, 2019 at 07:06 UTC

    Sorry to reply this late, but your result is different from what I wanted to achieve.

    Your parent and child read the same DATA once meaning: Every entry is read by either parent or child.

    I want to read DATA independently. Parent and child in my real world application need to have the same set of information to do different things with it.

    s$$([},&%#}/&/]+}%&{})*;#$&&s&&$^X.($'^"%]=\&(|?*{%
    +.+=%;.#_}\&"^"-+%*).}%:##%}={~=~:.")&e&&s""`$''`"e
[reply]
[d/l]
[select]

      See Re^3: How can I read DATA in parent and child? fdopen doesn't help, it's still the same shared seek pointer. *nix doesn't do what you want. If you want to do reads on handles, try this instead. 

      #!/usr/bin/perl

# https://perlmonks.org/?node_id=1230099

use strict;
use warnings;

open my $x, '<', \do { local $/; <DATA> };

my $who = fork() ? 'p' : 'c';

while( <$x> )
  {
  print "$who $_";
  }

1 while wait > 0;

__DATA__
a
b
c
d
e

      [download]
[reply]
[d/l]
      Parent and child in my real world application need to have the same set of information to do different things with it.

      Is this an XY Problem? The order of operations should then be:

      1. Read and store all the data
      2. Fork
      3. Process all the already-read data in different ways
[reply]

In Section Seekers of Perl Wisdom