http://qs321.pair.com?node_id=11111356


in reply to Possible precedence issue with control flow operator

I must admit that I'm a little surprised myself, but it turns out that or's precedence is so low that it is actually lower than return (probably because return is treated as a list operator). Which leads to the following result: 

perl -MO=Deparse -e "sub test { return int(rand(2)) or print 'Nope' }"
sub test {
    print 'Nope' unless return int rand 2;
}
-e syntax OK

[download]
I'm pretty sure this is not what you meant, because this would somehow try to do something in the sub after returning from it. I'm also not exactly sure what the return value of return itself would be :P.

Two ways to do what you want (beyond the one you already proposed), either with a temp variable: 

my $result;
$result = something() or croak "Something went wrong";
return $result;

[download]
Or, if this is the last line of your sub, you could remove the return altogether (if that's compatible with your coding rules): 
sub mySub
{
  ...
  something() or croak "Times are a'croaking";
}

[download]
The right way is the one that you like the most (again, respecting whatever coding rules should apply).

Replies are listed 'Best First'.
Re^2: Possible precedence issue with control flow operator
by Fletch (Bishop) on Jan 13, 2020 at 14:37 UTC

    When you're trying to suss out precedence problems the "-p" flag to B::Deparse can be useful to get it to shove in explicit parens everywhere. 

    $ perl -MO=Deparse,-p -e "sub test { return int(rand(2)) or print 'Nop
+e' }"
sub test {
    ((return int(rand(2))) or print('Nope'));
}
-e syntax OK

    [download]

    The cake is a lie.
    The cake is a lie.
    The cake is a lie.

[reply]
[d/l]
Re^2: Possible precedence issue with control flow operator
by ikegami (Patriarch) on Jan 13, 2020 at 18:12 UTC

    There's a third way: Parens can be used to override precedence. 

    return (
   something()
      or croak "Times are a'croaking"
);

    [download]
[reply]
[d/l]
Re^2: Possible precedence issue with control flow operator
by LanX (Saint) on Jan 13, 2020 at 18:48 UTC
    A return is evaluated in the context of the sub's caller.

    so this variant

    my $result;
$result = something() or croak "Something went wrong";
return $result;

    [download]

    is safer (resp. only correct) if it's supposed to be a scalar.

    Cheers Rolf
    (addicted to the Perl Programming Language :)
    Wikisyntax for the Monastery FootballPerl is like chess, only without the dice

[reply]
[d/l]

In Section Seekers of Perl Wisdom