In the assignment

(@complete_url, @filename) = ($_ =~ /$test_regexp/g)
[download]

all matches will be assigned to the array @complete_url. I would expect that you find the urls and filenames both in the array. So you have everything in one array and need to split it into two afterwards.

This. Your solution is fine, but you need to do a bit of postprocessing, e.g.

if (@groups = /$test_regexp/g) {
    while (@groups) {
        ($url, $file) = splice @groups, 0, 2;
        # ...
    }
}
[download]

or use a loop:

while (/$test_regexp/g) {
    ($url, $file) = ($1, $2);
    # ...
}
[download]

Thanks, that also solves my problem.

Thanks, this answers my original question. So in general, is it not possible to do a multi-array assignment in a single line, i.e.: (@a, @b) = <some_expression>

"So in general, is it not possible to do a multi-array assignment in a single line, i.e.: (@a, @b) = <some_expression>"

That's correct with the syntax you're using there; however, you can do it with references. Here's a rather contrived example to demonstrate.

#!/usr/bin/env perl -l

use strict;
use warnings;

my ($letters, $digits) = get_arrays();

print "Letters REF: $letters";
print "Letters: @$letters";
print for @$letters;
print "Digits REF: $digits";
print "Digits: @$digits";
print for @$digits;

sub get_arrays {
    my @three_letters = qw{A B C};
    my @three_digits = qw{1 2 3};
    return (\@three_letters, \@three_digits);
}
[download]

Output:

Letters REF: ARRAY(0x7ff684047ad0)
Letters: A B C
A
B
C
Digits REF: ARRAY(0x7ff684047938)
Digits: 1 2 3
1
2
3
[download]

If you're unfamiliar with references, a good place to start is "perlreftut - Mark's very short tutorial about references". In the "The Rest" section, you'll find links to more detailed documentation on this topic.

-- Ken

Special_K:

The URL part is always constant, so instead *just* capture the filenames, then build the URLs:

if (@filename = ($_ =~ /$test_regexp/g)) {
    my @complete_urls = map { "http://...." . $_ } @filename;
    ...
}
[download]

Alternatively, capture the URL and split off the filenames:

if (@complete_urls = ($_ =~ /$test_regexp/g)) {
    my @filename = map { s{^.*/}{}; $_ } @complete_urls;
    ...
}
[download]

...roboticus

When your only tool is a hammer, all problems look like your thumb.

$test_regexp = qr[url="(http://downloads\.bbc\.co\.uk/podcasts/worldse
+rvice/globalnews/ ... mp3))"];
[download]

Wow, I didn't even know you could change the beginning and ending delimiter of a regexp. Is that only if you use the qr function, or can you change the delimiter in any context?

"Is that only if you use the qr function, or can you change the delimiter in any context?"

Not "any", but certainly "many". Take a look at "perlop: Quote and Quote-like Operators".

-- Ken

You can do that with the quote and quote-like operators, but also, for regexes, with the m// and the s/// operators, which can be written, for example, m{...} and s[...]{...} or even m#...#, etc, as shown in the following Perl one-liners:

$ perl -e 'print $1 if "foobar" =~ m{f(oo)ba}'
oo

$ perl -e 'print $1 if "foobar" =~ m#f(oo)ba#'
oo
[download]

Update: well, thinking again about what I wrote above, m// and s/// are in fact part of the quote and quote-like operators (so Ken's answer said it all), but I just wanted to point out that this can be done in direct regex constructs.

I think I prefer roboticus's alternate suggestion to extract complete ULRs first, then extract the filename from each URL, but if it absolutely must be done "in one line", this might serve (Perl version 5.10+ needed for state built-in, but this could be an ordinary my variable in the for-loop outside the if statement):

>perl -wMstrict -le
"use 5.010;
 ;;
 use List::MoreUtils qw(part);
 ;;
 my $rx = qr{ \b ([[:alpha:]]+ (\d+)) \b }xms;
 ;;
 for my $s (
   'foo abc333 bar de4444 baz fghi22 xyzzy jk123 z',
   'zzz123 xx yyyy12 xx xx1234',
   ) {
   if (my @matches = part { state $i = 0;  $i++ % 2 } $s =~ m{ $rx }xm
+sg) {
     print qq{matched: full (@{$matches[0]}); digits (@{$matches[1]})}
+;
     }
   else {
     print 'no matches';
     }
   }
"
matched: full (abc333 de4444 fghi22 jk123); digits (333 4444 22 123)
matched: full (zzz123 yyyy12 xx1234); digits (123 12 1234)
[download]

See List::MoreUtils::part.

You can use a ternary to push onto either the complete URL array or the filename array. To save space I have simplified the URLs and pattern but the principle would still hold for your data. Things would get more complicated if your URLs broke across lines.

$ perl -Mstrict -Mwarnings -MData::Dumper -e '
open my $xmlFH, q{<}, \ <<EOF or die $!;
blarg http://a.b.co.uk/path/to/file.mp3 bloop http://x.y.com/stuff.mp3
blooble http://some.firm.com/downloads/glooble.mp3 sploffle
EOF

my $rx = qr{(?x) ( http:// .*? ( [^/]+ \.mp3 ) ) };
my( @comp, @fn );

my $xmlText = do {
   local $/;
   <$xmlFH>;
   };

push @{ $_ =~ m{^http://} ? \ @comp : \ @fn }, $_ for
   $xmlText =~ m{$rx}g;

print Data::Dumper->Dumpxs( [ \ @comp, \ @fn ], [ qw{ *comp *fn } ] );
+'
@comp = (
          'http://a.b.co.uk/path/to/file.mp3',
          'http://x.y.com/stuff.mp3',
          'http://some.firm.com/downloads/glooble.mp3'
        );
@fn = (
        'file.mp3',
        'stuff.mp3',
        'glooble.mp3'
      );
$
[download]

I hope this is helpful.

Update: Corrected unescaped dot in regex and added (?x) extended syntax to space things out for readability.