I think I might be misunderstanding the problem because it seems straightforward:

foreach (<DATA>) {
    my ($day)  = /(\d+)d/;
    my ($hour) = /(\d+)h/;
    $_ ||= 0 foreach $day, $hour;
    print "Day: ($day) Hour: ($hour)\n";
}

__DATA__
3d
3d 2h
6h
[download]

The prints:

Day: (3) Hour: (0)
Day: (3) Hour: (2)
Day: (0) Hour: (6)

Cheers,
Ovid

New address of my CGI Course.
Silence is Evil (feel free to copy and distribute widely - note copyright text)

Duh, I couldn't see the trees for the regex forest I had created...
Thanks for your clear thinking Ovid.
LogicalChaos

*snif* That's beautiful!

I regret that I have only one ++ vote to give to this note...

A little obfuscated, but I kind of like this method:

my %t = reverse ($value =~ /(\d+)([dh])/g);

my $day = $t{d} || 0;
my $hour = $t{h} || 0;
[download]

I Love You Folks^TM! I've never used 'g' outside of s/// before.
Thanks for the tip,
LogicalChaos

First. Your regexp is slightly wrong. It matches even strings like 'hello there 1d'. You would need one more (?:...) around the whole regexp except the ^ and $ to fix it. Currently the first alternative matches only at the start of the string, while the second only at the end. You want them to only match the whole string.

Anyway I would suggest something like this:

while (<STDIN>) {
    chomp;
    if ($_ and /^(?:(\d+)d)?(?:\s*(\d+)h)?$/i) {
        print "Days: $1, Hours: $2\n";
    } else {
        print "Doesn't match\n";
    }
}
[download]

Jenda
Always code as if the guy who ends up maintaining your code will be a violent psychopath who knows where you live.
   -- Rick Osborne

Edit by castaway: Closed small tag in signature

Hey Jenda,
This is the one I was looking for. Pointing out the relative stupidity of my regex. I was checking for empty string, but then lost the fact that I didn't need to require the 'd' or 'h' portion, thus allowing for the deletion of the '|'. And at one point, I did correctly have the ^(?:...)$ wrapping the entire match, but lost it in one of my incantations.
So, the final form I've chosen is:

if ( $value and $value !~ /^(?:(\d+)d)?(?:\s*(\d+)h)?$/i )
   {
   $result  = "Please only enter time in one of these three formats: '
+3d', '4d 3h', '22h'";
   }
else
   {
   $day = $1 || 0;
   $hour = $2 || 0;
   }
[download]

And it seems to work!
Thanks,
LogicalChaos

use strict;
use Date::Manip;

foreach (<DATA>) {
    chomp;
    next if /^$/;
    my @delta=split(/:/, ParseDateDelta($_));
    my ($day) = $delta[3];
    my ($hour) = $delta[4];
    print "$_\t=>\tDay: $day\tHour: $hour\n";
}

__DATA__
3d
3d 2h
6h
[download]

3d      =>      Day: 3  Hour: 0
3d 2h   =>      Day: 3  Hour: 2
6h      =>      Day: 0  Hour: 6
[download]

# Under Construction
[download]

Actually, I won't be using date manipulations much. This is in a ClearQuest project I'm implementing, and all I need to know is that there are 8 hours in a day. The info gathered will be presented in days/hours.
And, unless I mis-remember, Date::Manip has compiled code, which would make it very difficult for me to place in cqperl (which is derived from ActiveState 5.6.0 perl). I can put in Perl only modules, but wouldn't want to hazzard puting in DLL's (or whatever is used on Windows).
Thanks for your input,
LogicalChaos

Although the solution I was proposing may not be precisely the one you were looking for; I thought it was worth noting for sake of others who might stumble on your post and wonder about alternative ways of doing this. It also appears simpler than the regexp way :)

There should be absolutely no difficulty in getting Date::Manip to work with cqperl as the module "is written entirely in perl" (quote). Despite of the fact that it may increase the size of your final executable and/or also affect it's run-time speed, there is no other visible harm in using the module. As I had stated, it would be an overkill to use the module to simply decypher date and hour values from the sample input you provided. Nontheless, it does appear cleaner than using raw regexp ;)

_____________________

# Under Construction
[download]

A somewhat different approach. If you were using 5.8 the $^N is probably a better choice than $+ though it makes little difference in this case.

#! perl -sw
use strict;

for ('6d', '3h', '4d 3h','6D', '3H', '4D 3H') {
    our ($d,$h) = (0,0);
    print "$d days $h hours\n" if
        m[^
            (?: (\d+)d (?{ $d = $+ || '0' }) )?
            \s*
            (?: (\d+)h (?{ $h = $+ || '0' }) )?
        $]xi;
}
__END__
C:\test>test
6 days 0 hours
0 days 3 hours
4 days 3 hours
[download]

for ("2D 3h", "2d", "3h", "3h 2d", "Some string") {
   my ($day, $hour) = map {$_+0} /^(?:(\d+)d\s*)?(?:(\d+)h)?$/i; 
   $day || $hour ? print "Day - $day, hour - $hour\n" : warn "Wrong fo
+rmat $_"
}
[download]

if ($value =~ /^(\d+)d$/i) {
    $day = $1;
}
elsif ($value =~ /^(\d+)d\s+(\d+)h$/i) {
    $day = $1;
    $hour = $2;
}
elsif ($value =~ /^(\d+)h$/i) {
    $hour = $1;
}
else {
    print "Hork!\n";
}
[download]

Update: Sorry, just ignore this post. It's too ugly to live. ;)