sub sortByDate
{
    #get dates. will look like this: date:"2015-02-16",  "YYYY-MM-DD",
    my $aDate = $a =~ /date:\"(\d{4}\-\d{2}\-\d{2})"/;
    my $bDate = $b =~ /date:\"(\d{4}\-\d{2}\-\d{2})"/;

    return ($aDate cmp $bDate);
}
[download]

...should contain...

 
    my($aDate) = $a =~ /date\"(\d{4}-\d{2}-\d{2})"/;
    my($bDate) = $b =~ /date\"(\d{4}-\d{2}-\d{2})"/;
[download]

The regexp binding operator returns true/false (1 or 0) in scalar context, and the match contents in list context. The parens around your variable names place the return value of the =~ operator into list context.

By the way, even for small bits of JSON, I'd be inclined to convert them to a datastructure as the first thing I do, rather than treating the json as text.

Update: An example of treating the data as JSON:

use strict;
use warnings;
use JSON;
use Data::Dump;

my @data;

while (<DATA>) {
    next unless /\N/;
    push @data, decode_json($_);
}

print "Unsorted:\n";
dd \@data;

my @sorted = sort { $a->{date} cmp $b->{date} } @data;

print "\nSorted:\n";
dd \@sorted;

__DATA__
{ "date":"2015-03-01", "content":"asdf" }


{ "date":"2015-05-01", "content":"erwa" }
{ "date":"2015-01-02", "content":"erts" }

{ "date":"2014-04-02", "content":"w34r" }
[download]

...produces the following output:

Unsorted:
[
  { content => "asdf", date => "2015-03-01" },
  { content => "erwa", date => "2015-05-01" },
  { content => "erts", date => "2015-01-02" },
  { content => "w34r", date => "2014-04-02" },
]

Sorted:
[
  { content => "w34r", date => "2014-04-02" },
  { content => "erts", date => "2015-01-02" },
  { content => "asdf", date => "2015-03-01" },
  { content => "erwa", date => "2015-05-01" },
]
[download]

I did have to fix up your JSON, but I assume the real data you are working with is real JSON, not pseudo-JSON as the post seems to show. There are many reasons why I would prefer an approach that treats the input JSON as JSON rather than as strings, including:

• Easy detection of malformed input.
• As the input grows more complex, the solution scales up to encapsulate the complexity; you don't have to invent a new regexp every time the data takes a new turn.
• It's more convenient to deal with data structures internally. We should favor approaches that convert to the most convenient format as early as possible, and convert away from that most convenient format as late as possible... if we value reduced code complexity and fewer bugs.
• Someone has already written a JSON parser; you don't need to.

In scalar context, the match operator and thus the bind operator returns whether a match was found or not. You want to evaluate the match in list context to get it to return the list of matches.

Fix:

   my ($aDate) = $a =~ /\bdate:\s*"(\d{4}-\d{2}-\d{2})"/;
   my ($bDate) = $b =~ /\bdate:\s*"(\d{4}-\d{2}-\d{2})"/;
[download]

Also:

• Added \b to avoid catching enddate.
• Added \s* in case the JSON encoder decides to start adding whitespace.
• Removed some superfluous backslashes.

Note: Will break if you get

• { date:"\u0032015-05-01", content:"erwa" }
• { foo:{date:"2014-05-01"}, date:"2015-05-01", content:"erwa" }
• etc

For a reliable but slower solution, you can use

use JSON::XS qw( decode_json );

my @sorted =
   map { substr($_, 10) }
      sort
         map { decode_json($_)->{date} . $_ }
            @events;
[download]

As for the blank lines, just remove them first using

@events = grep /\S/, @events;
[download]

Update: Added to my answer.

You beat me to your solution.

The why is context. Specifically, the original is in scalar context, which will return the size of the set of matched values (1)true or false. So your two values are both 1, and now (iirc) being a stable sort, returns the dates in the original order. The update takes the return value in list context, causing the results of the matches to be assigned to the provided variables.

Update: test my understanding of the return value from a pattern match, and correct the statement.

What's going on here? ... What is the difference between parentheses absent and parentheses present?

As others have said: context. Please see Tutorials->Context in Perl->Context tutorial right here on the premises.

Pull out only the date lines using grep.

@events = sort sortByDate grep { /date:/ } @events;
[download]