http://qs321.pair.com?node_id=11135292

nysus has asked for the wisdom of the Perl Monks concerning the following question:

Monks, I was toying around with importing/requiring to improve my aptitude with them. So I have this package: 
#! /usr/bin/env perl
package A;

require Exporter;
our @ISA = qw(Exporter);
our @EXPORT_OK = qw (sub1 $var);
our %EXPORT_TAGS = (all => [ qw(sub1 $var) ]);

our $var = 7;

sub sub1 {
  print "this\n";
}

1;

[download]

I want to use require to import the $var global. I try this: 

#! /usr/bin/env perl

use strict;
use warnings;

use lib '.';
require A;
A->import (':all');

sub1();
print $var . "\n";

[download]

This script throws Global symbol "$var" requires explicit package name (did you forget to declare "my $var"?).

But I have no such error with Use A like so: 

#! /usr/bin/env perl

use strict;
use warnings;

use lib '.';
use A ':all';

print $var . "\n";

[download]

So I have a gap in my knowledge. I'm not sure why the second way works and the first doesn't. Any guidance is appreciated. Thanks!

$PM = "Perl Monk's";
$MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon Curate Priest Vicar";
$nysus = $PM . ' ' . $MCF;
Click here if you love Perl Monks

Replies are listed 'Best First'.
Re: How do I import a global variable form a package with require?
by choroba (Cardinal) on Jul 22, 2021 at 13:53 UTC
    A->import happens at runtime, but use happens at compile time. The strict check happens at compile time, too, so use a BEGIN block to run the import before the variable is encountered: 
    BEGIN {
    require A;
    A->import(':all');
}
print $var;

    [download]
    map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]
[reply]
[d/l]
[select]
      Alternatively, declare the variable for the compiler. The call to import then assigns the value. This prints 7 (with your A.pm): 
      #! /usr/bin/env perl

use strict;
use warnings;

our $var;

use lib '.';
require A;
A->import (':all');

print $var . "\n";

      [download]
[reply]
[d/l]
[select]

      Ah, yes, I remember that. However, what if I want to only import $var at runtime? Am I just stuck fully qualifiying it with A::var? And I still don't get why sub1 imports just fine with require and $var doesn't.

      $PM = "Perl Monk's";
      $MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon Curate Priest Vicar";
      $nysus = $PM . ' ' . $MCF;
      Click here if you love Perl Monks

[reply]
[d/l]
[select]
        > what if I want to only import $var at runtime?

        What does it mean? If you have code that will be compiled at runtime, it works: 

        require A;
A->import('$var');
eval 'print $var; 1' or warn $@;

        [download]

        > why sub1 imports just fine with require and $var doesn't

        Strict checks that variables are declared before you use them. It doesn't check subs when it's sure it's a sub, i.e. when parentheses follow the sub name. Try using sub1 without parentheses: the compiler will only see a bareword, not a sub call, and will complain.

        Update: reworded.

        map{substr$_->[0],$_->[1]||0,1}[\*||{},3],[[]],[ref qr-1,-,-1],[{}],[sub{}^*ARGV,3]
[reply]
[d/l]
[select]
      A reply falls below the community's threshold of quality. You may see it by logging in.

Back to Seekers of Perl Wisdom