G'day nysus,

Writing the Dumper output to a file, manually opening that file, manually copying its contents, then manually pasting into a script, does not seem like a very sensible way to go. Even if you're using less manual steps — e.g. 'cat dumper.out >> script.pl' or 'G:r dumper.out' from 'vim script.pl' — I still wouldn't recommend it. You should not have to edit your code every time the data changes. Consider reading the Dumper output directly in your script.

"I tried getting rid of $VAR1 ..."

Perhaps Data::Dump would be a better choice:

$ perl -e '
    use Data::Dumper;
    use Data::Dump;
    my $x = { a => 1, b => [1,2,3] };
    print "*** From Data::Dumper ***\n";
    print Dumper $x;
    print "*** From Data::Dump ***\n";
    dd $x;
'
*** From Data::Dumper ***
$VAR1 = {
          'b' => [
                   1,
                   2,
                   3
                 ],
          'a' => 1
        };
*** From Data::Dump ***
{ a => 1, b => [1, 2, 3] }
[download]

Also take a look at Storable, JSON and YAML (those last two also have XS versions which will be faster).

Thanks, yes, I'm aware. My code is more or less an experiment on how to use the __DATA__ feature with dumped data. The data I dumped took several minutes to generate so I didn't really feel like re-running the code that generated it in the first place. Figured I'd try a "shortcut" which took longer than re-rerunning the code. But hey, I learned something.

$PM = "Perl Monk's";
$MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon Curate Priest Vicar";
$nysus = $PM . ' ' . $MCF;
Click here if you love Perl Monks

To get rid of $VAR1 I set $Data::Dumper::Terse = 1; (also relevant $Data::Dumper::Varname).

The idiom I use for eval'ing is:

my $result = eval { $hash };
if( $@ || ! $result ){ die "error eval: $@" }
[download]

For "undumping" there is also Data::Undump which claims to be secure, I guess that's in reference to the eval? But it's not clear to me.

There is also the Safe module for evaluating untrusted input while limiting possible damage.

There is also the Safe module for evaluating untrusted input while limiting possible damage.

That way requires a LOT of trust in the safety of Safe. One error in Safe or simply in the actual configuration of Safe and you are in BIG trouble.

The safe way of saving and restoring data is to handle it as data, not as code. See also Re: Accessing variables in an external hash without eval, Re^4: Accessing the hash name in perl, Re^2: DBI fetchall_hashref convert to scalar, Re^2: DBI fetchall_hashref convert to scalar, Re: What's the right way to include a config file as a .pm bareword?.

Alexander

--
Today I will gladly share my knowledge and experience, for there are no sweeter words than "I told you so". ;-)

OK, noodled with this some more. This worked:

use Data::Dumper qw(Dumper);
use warnings;
use strict;
my $hash;
{
    local $/;
    $hash = <DATA>;
}

my $VAR1;
eval $hash;
print keys %$VAR1;

__DATA__
$VAR1 = {
          'blah.com' => [
                                             '212.235.56.176'
                                            ],
            'blah.org' => [
                                  '212.235.56.176'
                                ],
            'www.boo.org' => [
                                 '212.235.56.176'
                               ],
};
[download]

Originally, I was using eval like I was running a block of code, but that's not what I wanted.

use strict;
use warnings;
use Data::Dumper qw(Dumper);
my $hash;
{
    local $/;
    $hash = <DATA>;
}
#$hash = eval { $hash };
 $hash = eval   $hash  ;
 print keys %$hash; # error   (no more)

  __DATA__
  #$VAR1 = {
           {
            'blah.com' => [
                                               '212.235.56.176'
                                             ],
            'blah.org' => [
                                  '212.235.56.176'
                                ],
            'www.boo.org' => [
                                 '212.235.56.176'
                               ],
};
[download]

OUTPUT:

C:\Users\Bill\forums\monks>perl 11116141.pl
blah.comblah.orgwww.boo.org
[download]

{ blah.com' => [ doesnt look right

I accidentally deleted the apostrophe. It's fixed.

$PM = "Perl Monk's";
$MCF = "Most Clueless Friar Abbot Bishop Pontiff Deacon Curate Priest Vicar";
$nysus = $PM . ' ' . $MCF;
Click here if you love Perl Monks

Shameless plug: You might be interested in my module Data::Undump::PPI. It uses a static parse so it's safer than eval.

I dumped a hash into a file and then copied into the __DATA__section of my script.

Although I wouldn't recommend this for real-world use (use a config file instead), see my reply in the thread Is it possible to modify __DATA__ via the DATA file handle or otherwise? for a script that modifies its own __DATA__ section:

use warnings;
use strict;
use File::Replace 'replace3';
use Data::Undump::PPI qw/Dump Undump/;

my $pos = tell DATA;
my $data = Undump(fh => *DATA);

$data->{counter}++;

my (undef,$outfh,$repl) = replace3(__FILE__,':raw');
$repl->copy($pos);
Dump([$data], fh=>$outfh);
$repl->finish;

__DATA__
$VAR1 = {
          counter => 0
        };
[download]