The strftime() function from POSIX might be what you need.

$ perl -Mstrict -Mwarnings -MPOSIX=strftime -e '
my $mno = 0;
my %monthLookup = map { $_ => $mno ++ }
   qw{ Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec };

open my $inFH, q{<}, \ <<EOD or die $!;
1-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,0.00,0.00,0.00,0.00,0.00
2-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,0.00,0.00,0.00,0.00,0.00
3-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,11.60,11.60,11.60,11.60,11.6
+0
EOD

while ( <$inFH> )
{
    my $date = ( split m{,} )[ 0 ];
    my( $d, $m, $y ) = split m{-}, $date;
    print strftime( qq{$date is day %j\n},
       0, 0, 0, $d, $monthLookup{ $m }, $y - 1900 );
}'
1-Apr-2012 is day 092
2-Apr-2012 is day 093
3-Apr-2012 is day 094
$
[download]

I hope this is helpful.

$doy = Day_of_Year($year,$month,$day);
[download]

If parsing dates doesn't work out so well without an explicit format, you can fall back on POSIX::strptime.

Another use of POSIX::strptime:

use strict;
use warnings;
use POSIX::strptime;

while (<DATA>) {
    my ($date) = /^([^,]+)/;
    my $doy = ( POSIX::strptime( $date, '%d-%b-%C' ) )[-1] + 1;
    print "Date: $date; DOY: $doy\n";
}
__DATA__
1-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,0.00,0.00,0.00,0.00,0.00
2-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,0.00,0.00,0.00,0.00,0.00
3-Apr-2012,615265,2.4,0,0,0,0,0,0,0,0,0,0,11.60,11.60,11.60,11.60,11.6
+0
[download]

Output:

Date: 1-Apr-2012; DOY: 92
Date: 2-Apr-2012; DOY: 93
Date: 3-Apr-2012; DOY: 94
[download]

Hope this helps!

print Time::Piece->strptime($date_str, "%d-%b-%Y")->yday(),"\n";
[download]

Try the Date::Manip module.

use Date::Manip;
$day_of_year = 0 + UnixDate("3-Apr-2012", "%j");
[download]

A follow-on question that might help clarify your decision is ... “what else do you need to do with, or know about, that date?”   What future requirements might you anticipate, e.g. from the Marketing Department?   Sometimes, a kitchen-sink is just what the doctor ordered ... taking the entire date-handling issue off your hands.

guys,

thanks so much for your replies. These look helpful. I will let you know how I get on. Ideally, I will be able to use that code to add another field to the table and be off and running.

many thanks again, from a first time perl user. Tim

Guys, sorry to be a pain, but I'm having trouble installing the POSIX strptime module. I'm using a windows machine at work and trying to use Perl Package Manager to find the module. (It wasn't there).

So, I've downloaded the strptime module from here (http://search.cpan.org/~gozer/POSIX-strptime-0.05/lib/POSIX/strptime.pm)

I've unpacked the folders in c:Perl64/site/lib and c:Perl64/lib, but my perl script is still not seeing that package. It is saying:

can't locate loadable object for module POSIX::strptime in @INC...

any advice would be gratefully recieved.

Thanks

Tim