# The first time [[ use do_compile_time_arg_check; ]]
# or [[ use do_compile_time_arg_check (); ]] is used,
# the first command line arg is removed from @ARGV if
# it's [[ --log ]] or [[ --log="file name" ]].

# Whenever [[ use do_compile_time_arg_check; ]] is used
# (including the first time),
#
# - [[ LOGGING ]] is exported as a constant sub. It returns
#   true if [[ --log ]] or [[ --log="file name" ]] was found
#   at the head of the argument list the first time this
#   module was used.
#
# - [[ $LOG_FILE_NAME ]] is exported as a strict-safe global.
#   It contains the file name from [[ --log="file name" ]] if
#   that argument was found at the head of the argument list
#   the first time this module was used.

use strict;
use warnings;

package do_compile_time_arg_check;

use vars qw(
   $log
   $log_file
);

BEGIN {
   if (@ARGV && $ARGV[0] =~ /^-?-log(?:=(.*))?$/) {
      shift(@ARGV);
      $log = 1;
      $log_file = $1;
   }
}

sub import {
   my $caller_pkg = caller();

   my $lexical_log = $log;

   {
      no strict 'refs';
      *{"${caller_pkg}::LOGGING"      } = sub () { $lexical_log };
      *{"${caller_pkg}::LOG_FILE_NAME"} = \$log_file;
   }
}

1;