#! /usr/bin/perl -w

use strict;
use LWP::UserAgent;

my @cartridge = qw/ name part percent remain coverage low serial printed /;
my @kit       = qw/ name part percent remain /;

for my $host( @ARGV ) {
    my $url = qq{http://$host/hp/device/this.LCDispatcher?dispatch=html&cat=0&pos=2};
    my $response = LWP::UserAgent->new->request( HTTP::Request->new( GET => $url ));
    if( !$response->is_success ) {
        warn "$host: couldn't get $url: ", $response->status_line, "\n";
        next;
    }
    $_ = $response->content;

    my (@s) = grep { defined $_ } m{
        (?:
            >         # closing tag
            ([^<]+)   # text (name of part, e.g. q/BLACK CARTRIDGE/)
            <br>
            ([^<]+)   # part number (e.g. q/HP Part Number:     HP C9724A/)
            </font>\s+</td>\s*<td[^>]+><font[^>]+>
            (\d+)     # percent remaining
        )
        |
        (?:
            (?:
                (?:
                    Pages\sRemaining # different text values
                    | Low\sReached
                    | Serial\sNumber
                    | Pages\sprinted\swith\sthis\ssupply
                )
                    :
                    \s*</font></p>\s*</td>\s*<td[^>]*>\s*<p[^>]*><font[^>]*>\s* # separated by this
                |
                Based\son\shistorical\s\S+\spage\scoverage\sof\s # or just this, within a <td>
            )
            (\w+) # and the value we want
        )
    }gx;

    my %res;
    @{$res{K}}{@cartridge} = @s[ 0.. 7];
    @{$res{X}}{@kit}       = @s[ 8..11];
    @{$res{C}}{@cartridge} = @s[12..19];
    @{$res{F}}{@kit}       = @s[20..23];
    @{$res{M}}{@cartridge} = @s[24..31];
    @{$res{Y}}{@cartridge} = @s[32..39];

    print <<END_STATS;
$host
    Xfer $res{X}{percent}% $res{X}{remain}
    Fuse $res{F}{percent}% $res{F}{remain}
    C $res{C}{percent}% cover=$res{C}{coverage}% left=$res{C}{remain} printed=$res{C}{printed}
    M $res{M}{percent}% cover=$res{M}{coverage}% left=$res{M}{remain} printed=$res{M}{printed}
    Y $res{Y}{percent}% cover=$res{Y}{coverage}% left=$res{Y}{remain} printed=$res{Y}{printed}
    K $res{K}{percent}% cover=$res{K}{coverage}% left=$res{K}{remain} printed=$res{K}{printed}
END_STATS
}