use constant SPIRIT_VERSION => '1.2';
use constant SPIRIT_URL     => 'http://www.spiritconsortium.org/XMLSchema/SPIRIT/' . SPIRIT_VERSION;


=head2 validate_file

  validate_file ( $file, $ressucitate )

Validates SPIRIT DOM against its XML-Schema. Uses document URI unless $ENV{SOCK_SCHEMA_LOCATION} is defined.
Backbone is Apache Xerces library, only used in SOCK for validation purposes. Expires unless $ressucitate is set.
Returns validation errors.

=cut

sub validate_file {
  my ( $file, $ressucitate ) = @_;
  
  assert_nonblank $_[0];
  
  if ( $ENV{SOCK_SCHEMA_LOCATION} ) {
    expire "Could not find any '$ENV{SOCK_SCHEMA_LOCATION}' directory!" unless -d $ENV{SOCK_SCHEMA_LOCATION};
  }
  
  say "Validating '$file' file...";
  
  XML::Xerces::XMLPlatformUtils::Initialize ();

  my $parser = XML::Xerces::SAXParser->new;

  my $options = {
    setDoNamespaces                 => 1,
    setDoSchema                     => 1,
    setErrorHandler                 => XML::Xerces::PerlErrorHandler->new,
    setExitOnFirstFatalError        => 0,
    setExternalSchemaLocation       => SPIRIT_URL . ' ' . ( $ENV{SOCK_SCHEMA_LOCATION} || SPIRIT_URL ) . '/index.xsd',
    setValidationConstraintFatal    => 0,
    setValidationSchemaFullChecking => 1,
    setValidationScheme             => $XML::Xerces::AbstractDOMParser::Val_Always,
  };

  $parser->$_ ( $options->{$_} ) for keys %$options;

  eval { $parser->parse ( $file ) };
  my $error = $@;
     $error = $error->getMessage if ref $error;
  
  XML::Xerces::XMLPlatformUtils::Terminate ();
  
  if ( $error ) {
    $error =~ s/ERROR:/Validation error:/;
    $error =~ s/\s+ at .+ line \d+\n//;
    $error =~ s/\n/\n---   /g;
    
    expire $error unless $ressucitate;
    
    counsel $error;
  }

  say "Done.";
  
  $error;
}