#!/usr/bin/env perl

use Data::Dumper;
use English('-no_match_vars');
use Getopt::Long::Descriptive;
use Params::Validate(':all');
use Readonly;
use Text::Diff;
use Try::Tiny;
use 5.01800;
use warnings;

Readonly my $VALUE_OF=>qr{\| *VALUE *= *};
Readonly my $HASHREF=>{ type=>HASHREF };

use Getopt::Long::Descriptive;

my ($opts,$usage)=describe_options(
    "$0 %o <some-arg>",
    ['input|i=s','path to input file'],
    [],
    ['verbose|v','print extra stuff'],
    ['help',"print usage message and exit", { shortcircuit => 1 } ],
);
print($usage->text), exit
    if ($opts->help || !$opts->input);
warn Data::Dumper->Dump([\$opts],[qw(opts)]),' '
    if ($opts->verbose);

my @failed;
open my $INPUT,'<',$opts->input
    or die qq{Could NOT open '$opts->input' for reading! $OS_ERROR};
local $INPUT_RECORD_SEPARATOR=qq{\n\n};
while (<$INPUT>) {
    chomp;
    warn Data::Dumper->Dump([\$ARG],[qw(*_)]),' '
        if ($opts->verbose);
    my $_href;
=strike: Example of input
    NAME|VALUE = a
    TASK|VALUE = copy
    CAPS|VALUE = 0
    PKG_TYPE|VALUE = premium

=cut
    ()=m{^(?<name>.+?)$VALUE_OF(?<value>\S*) *$(?{$_href->{uc $+{name}}=$+{value}})}gsm;
    push @failed,treat($_href);
    warn "\n\n";
    };
close $INPUT
    or die qq{Could NOT close '$opts->input' after reading! $OS_ERROR};
# Dump
warn Data::Dumper->Dump([\@failed],[qw(*failed)]),' ';
exit;

    sub treat {
        my ($_HREF)=Params::Validate::validate_pos(@_,$HASHREF );
        warn Data::Dumper->Dump([\$_HREF],[qw(*_HREF)]),' '
            if ($opts->verbose);

        my @return;
        # If NAME and TASK are NOT to be replaced use
        #my $file="@{[delete $_HREF->{NAME}]}_@{[delete $_HREF->{TASK}]}.txt";
        # otherwise use
        my $file="$_HREF->{NAME}_$_HREF->{TASK}.txt";
        #
        my $keys=join q{|},keys %{$_HREF};
        my $_re=qr{(?<name>$keys)$VALUE_OF(?<value>\S*)}i;
        warn Data::Dumper->Dump([\$_re],[qw(*_re)]),' '
            if ($opts->verbose);
        try {
            my $before;
            open my $INPUT,'<',"input/$file"
                or die qq{Could NOT open 'input/$file' for reading! $OS_ERROR};
            local $INPUT_RECORD_SEPARATOR;
            $before=<$INPUT>;
            close $INPUT
                or die qq{Could NOT close 'input/$file' after reading! $OS_ERROR};

            my $after=$before=~ s{$_re(?{ warn Data::Dumper->Dump([\%+],[qw(*+)]),' 'if $opts->verbose; })}{$+{name}|VALUE = $_HREF->{uc $+{name}}}gimrs;
            #my $after=$before=~ s{$_re}{$+{name}|VALUE = $_HREF->{uc $+{name}}}gimrs;

            warn Data::Dumper->Dump([\diff(\$before,\$after)],[qw(*difference)]),' '
                if ($opts->verbose);

            open my $OUTPUT,'>',"output/$file"
                or die qq{Could NOT open 'output/$file' for writing! $OS_ERROR};
            print {$OUTPUT} $after;
            close $OUTPUT
                or die qq{Could NOT close 'output/$file' after writing! $OS_ERROR};

            # success
            @return=();
            }
        catch { # Record failure
            @return=("input/$file\t$OS_ERROR");
            Carp::cluck $ARG
                if ($opts->verbose);
            };

        return @return;
        }; # treat