comment on

A complete working sample using Data::Dumper where an object having a DateTime reference can be printed in short and long versions depending on $Data::Dumper::Freezer:

# Foo.pm
package Foo;
use strict;
use warnings;
use DateTime;

sub new {
    my $class = shift;
    my $self = { _timevalue => DateTime->now, };
    bless( $self, $class );
    return $self;
}

# Modify _timevalue and return blessed reference
sub _dumper_hook {
    $_[0] = bless {
        %{ $_[0] },
        _timevalue => $_[0]->{_timevalue}->ymd . q{ }
          . $_[0]->{_timevalue}->hms,
      },
      ref( $_[0] );
}

1;
__END__
[download]

Test:

# Foo.t:

use strict;
use warnings;
use Data::Dumper;
use Test::More;

plan tests => 2;

use Foo;
my $f = Foo::->new;
{
    local $Data::Dumper::Freezer = '_dumper_hook';
    like(
        Dumper($f),
        qr/\d{4}-\d{2}-\d{2}\s\d{2}:\d{2}:\d{2}/,
        q{prints short version}
    );
}

unlike(
    Dumper($f),
    qr/\d{4}-\d{2}-\d{2}\s\d{2}:\d{2}:\d{2}/,
    q{prints long version}
);

__END__
[download]

Run:

$ perl Foo.t
1..2
ok 1 - prints short version
ok 2 - prints long version
$
[download]

--
No matter how great and destructive your problems may seem now, remember, you've probably only seen the tip of them. [1]

In reply to Re: Condensed output of Data::Dumper used on DateTime by andreas1234567
in thread Condensed output of Data::Dumper used on DateTime by andreas1234567

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


The stupid question is the question not asked
	PerlMonks