comment on

Since eyepopslikeamosquito laid out a breif history of the JAPH, I figured I might as well add one of the few that I ever wrote. I'm not much into obfus or code in sigs or what not, but I did have an idea for a JAPH after watching The Matrix a couple times, and up until then I hadn't seen anyone use the entire screen and rand() to make the right string pop up.

I did have a obfuscated version of this somewhere, but I can't find it. Just remove most of the whitespace and shorten all the variable names.

Update: fixed eyepopslikeamosquito (twice) :(

#!/usr/bin/perl -w
use strict;

use Curses;

my @LETTERS = ( 'A' .. 'Z', 'a' .. 'z', ',', ' ' );
$SIG{TERM} = sub { exit };

my $STRING = 'Just Another Perl Hacker,';
my $LENGTH = length $STRING;

initscr;

my $ROW    = ( LINES() % 2 ? LINES() - 1 : LINES() ) / 2;
my $COLUMN = ( COLS() % 2 ? COLS() - 1 : COLS() ) / 2 - 
    ( $LENGTH % 2 ? $LENGTH - 1 : $LENGTH ) / 2;
my $END_COL = $COLUMN + $LENGTH - 1;

my @array;
my $count = 0;

my $x = random( LINES );
my $y = random( COLS );
my $letter = sub { $LETTERS[ int( rand( @LETTERS ) ) ] };

while( 1 )
    {
    my $x      = &$x;
    my $y      = &$y;
    my $letter = &$letter;
    
    next if( $x == $ROW and $array[$y] );
    
    if( $x == $ROW and $y >= $COLUMN and $y <= $END_COL
        and substr( $STRING, $y - $COLUMN, 1 ) eq $letter )
        {
        $array[$y]++;
        $count++;
        }
        
    put_letter( $letter, $x, $y );
    
    if( $count == $LENGTH ) { @LETTERS = ' '; }
    
    }
    
sub random
    {
    my $range = shift;
    
    sub {  int ( rand ( $range ) ) }
    }
    
sub put_letter
    {
    my ($letter, $x, $y) = @_;
    
    addch( $x, $y, $letter );
    
    refresh;
    }
[download]

--
brian d foy <bdfoy@cpan.org>

In reply to A curses-based JAPH by brian_d_foy

Are you posting in the right place? Check out Where do I post X? to know for sure.
Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:
<code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>
Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
Want more info? How to link or How to display code and escape characters are good places to start.


good chemistry is complicated, and a little bit messy -LW
	PerlMonks