Description

For win32 platforms only. Win32::OLE module gives you Automation access to Windows applications such as Word, Excel, Access, Rational Rose, Lotus Notes, and many others. Which means that your Perl scripts can harness these applications' capabilities, data and methods. Other Win32 perl modules build on this module (for example DBD::ADO, the DBI driver for Access data base).

The module lets you create perl objects that act as proxies for the application and it's components in your script. In the example below, $word is your perl proxy connected to a running instance of Word. You can call Word's Automation methods as perl methods on this object, and access the Word properties as hash elements in your perl object.

Automation-friendly Win32 applications expose hierarchies of objects and collections. The module ties these to Perl hashes and arrays for you. Your script just has to navigate the hierarchy and invoke the methods and properties as needed.

How do you know what methods and properties these objects support? Well, you RTFM that comes with the applications, and you use Object browsers that display a minimal documentation extracted from objects themselves (actually from their type libraries). The Win32::OLE module comes with Browser.html, a client-side dynamic html page. The perl code embedded in this page uses Win32::OLE to extract information from type libraries, and displays it in the html browser (IE required).

A short example will illustrate

    #! perl -w
    use strict;
    use Win32::OLE;
    use Win32::OLE::Const 'Microsoft Word';
    ### open Word application and add an empty document
    ### (will die if Word not installed on your machine)
    my $word = Win32::OLE->new('Word.Application', 'Quit') or die;
    $word->{Visible} = 1;
    my $doc = $word->Documents->Add();
    my $range = $doc->{Content};

    ### insert some text into the document
    $range->{Text} = 'Hello World from Monastery.';
    $range->InsertParagraphAfter();
    $range->InsertAfter('Bye for now.');

    ### read text from the document and print to the console
    my $paras = $doc->Paragraphs;
    foreach my $para (in $paras) {
        print ">> " . $para->Range->{Text};
    }

    ### close the document and the application
    $doc->SaveAs(FileName => "c:\\temp\\temp.txt", FileFormat => wdFor
+matDocument);
    $doc->Close();
    $word->Quit();
[download]

Why use Win32::OLE

You work on a win32 platform and you want to tap into existing applications from your Perl scripts.
You work on creating Automation components and you want to use Perl to test them.

Why not use Win32::OLE

You don't work on a win32 platform
You do, but you prefered scripting language is VBScript (just kidding ;-)

Where is the doc, tuts and code

The module and it's html doc are included in the ActiveState Perl installation. Look up the TPJ article by Jan Dubois, the module's coauthor, for an extended example. Doc is also found on CPAN mirrors
If you want to study the module code, it is on CPAN (6700+ lines in ole.xs and 2500+ lines of perl in several packages - good reading).
For introductory tutorials, check the ppt presentation and demos ( Word, Excel)
Not enough ? You can find more short tutorials down under ...

---

---

• Are you posting in the right place? Check out Where do I post X? to know for sure.
• Posts may use any of the Perl Monks Approved HTML tags. Currently these include the following:

  <code> <a> <b> <big> <blockquote> <br /> <dd> <dl> <dt> <em> <font> <h1> <h2> <h3> <h4> <h5> <h6> <hr /> <i> <li> <nbsp> <ol> <p> <small> <strike> <strong> <sub> <sup> <table> <td> <th> <tr> <tt> <u> <ul>

• Snippets of code should be wrapped in <code> tags not <pre> tags. In fact, <pre> tags should generally be avoided. If they must be used, extreme care should be taken to ensure that their contents do not have long lines (<70 chars), in order to prevent horizontal scrolling (and possible janitor intervention).
• Want more info? How to link or How to display code and escape characters are good places to start.