Your method was almost there --- you just need to make the following change:

# change this:
    $defines{$_} =~ s/<(\w+)>/$defines{$1}/g;

# to this:
    1 while $defines{$_} =~ s/<(\w+)>/$defines{$1}/g;
[download]

Doing just a single s///g can still leave you with unresolved defines (when the substituted text contains unresolved defines). Using the '1 while...' version continues to reapply the regex until all of the defines are resolved (or forever in the case of circular relationships). Here is an alternate version of your routine that returns a reference to the resolved %defines hash rather than a single option:

    #!/usr/bin/perl -w
    use strict;

    sub parse_defines {
        my $file = shift;
        open(FILE, $file) || die "can't open $file: $!";
        my %defines;
        while(<FILE>){
            next unless /^#DEFINE\s+<(\w+)>\s+(.*)/;
            $defines{$1} = $2;
        }
        for (values %defines) {
            1 while s/<(\w+)>/$defines{$1}/;
        }
        return \%defines;
    }

    my $opts = parse_defines('defs.txt');

    my $file = $opts->{FILE};
    print "$file\n";
[download]

Note: it also loops through and modifies the hash values in place rather than accessing each one via a key --- IIRC, having values return the actual values instead of copies is a 5.6ism, so you may stick with your method of looping over the keys for portability.