#!/usr/bin/env perl

use strict;
use warnings;

use Date::Manip;
use Lingua::EN::Numbers::Ordinate;

my $date = Date::Manip::Date->new();
$date->parse('2019-07-31');

my $month = $date->printf('%m');
$month =~ s/^0+//g;
my $dayofyear = $date->printf('%j');
$dayofyear =~ s/^0+//g;
my $dayofmonth = $date->printf('%d');
$dayofmonth =~ s/^0+//g;
my $year = $date->printf('%Y');

# December starts on 1st of September...
my $septstart = Date::Manip::Date->new();
$septstart->parse($year . '-09-01');
my $septday = $septstart->printf('%j');
$septday =~ s/^0+//g;

my $outstring = '';
if($month == 8) {
    # August
    $outstring = ordinate($dayofmonth) . ' August ' . $year;
} else {
    # December
    if($month > 8) {
        my $daycount = $dayofyear - $septday + 1;
        $outstring = ordinate($daycount) . ' December ' . $year
    } else {
        # Uh-oh, this is the continuation of last years december...
        my $decend = Date::Manip::Date->new();
        $decend->parse($year . '-12-31');
        my $decday = $decend->printf('%j');
        $decday =~ s/^0+//g;
        my $prevyeardays = $decday - $septday + 1;
        my $daycount = $dayofyear + $prevyeardays;
        $year--; # previous years december
        $outstring = ordinate($daycount) . ' December ' . $year
    }
}

print $outstring, "\n";
[download]

Ok, that was quite a lot, let's go through it step by step:

#!/usr/bin/env perl

use strict;
use warnings;

use Date::Manip;
use Lingua::EN::Numbers::Ordinate;

my $date = Date::Manip::Date->new();
$date->parse('2019-07-31');
[download]

The scripts starts with the usual boilerplate stuff, then loads Date::Manip. We also load Lingua::EN::Numbers::Ordinate, because that helps us to turn the number "1" into "1st", "2" to "2nd" and whatever else you crazy english speaking people do to numbers ;-)

We also make a Date::Manip::Date object with the date we want to turn into an EternalDecembertm date (this is a simple test script, no interactivity required).

my $month = $date->printf('%m');
$month =~ s/^0+//g;
my $dayofyear = $date->printf('%j');
$dayofyear =~ s/^0+//g;
my $dayofmonth = $date->printf('%d');
$dayofmonth =~ s/^0+//g;
my $year = $date->printf('%Y');
[download]

In this step, we extract some values out of the date object. We need to know the year, the month, the day of the month (in case of August) and the day of the year (in case of not-August). We also remove leading zeros from the strings. The CPAN module does some extra stuff, but for the date calculation test this is enough.

# December starts on 1st of September...
my $septstart = Date::Manip::Date->new();
$septstart->parse($year . '-09-01');
my $septday = $septstart->printf('%j');
$septday =~ s/^0+//g;
[download]

In case of not-August, we need to know the day of the year for the first of September as well (e.g. the first day of our EternalDecember). For this, we use the year extracted from the original date.

my $outstring = '';
if($month == 8) {
    # August
    $outstring = ordinate($dayofmonth) . ' August ' . $year;
[download]

August is easy, we just basically reassemble the string based on the original date values.

} else {
    # December
    if($month > 8) {
        my $daycount = $dayofyear - $septday + 1;
        $outstring = ordinate($daycount) . ' December ' . $year
[download]

If the original date involves the months september, october, november or december, we just calculate the number of days since first of september, call it december and we are good.

    } else {
        # Uh-oh, this is the continuation of last years december...
        my $decend = Date::Manip::Date->new();
        $decend->parse($year . '-12-31');
        my $decday = $decend->printf('%j');
        $decday =~ s/^0+//g;
        my $prevyeardays = $decday - $septday + 1;
        my $daycount = $dayofyear + $prevyeardays;
        $year--; # previous years december
        $outstring = ordinate($daycount) . ' December ' . $year
    }
}
[download]

This is the special case of the lot. When the original date is before August, in our calendar this is still last years december. So need to add all the days beginning from last years 1st of September to year end, plus all the days in the current year up to our original date (e.g. day of the year).

You may note here that i don't account for the previous year being a leap year when getting the "day of the year" values for september-december. While leap years shift the offset of those days by one, they shift BOTH offsets at the same time. Since we calculate the difference, this will still result in the correct value.