my %hash = (
  response => {
    blogs    => [
      {
        url     => 'equipo.tumblr.com',
        name    => 'equipo',
        updated => 1346015230,
      },
      {
        url     => 'linux.tumblr.com',
        name    => 'linuxmint',
        updated => 1345967468,
      },
    ],
  },
);
my @urls = map { $_->{url} } @{$hash{response}{blogs}};
[download]

perldoc perlreftut and peldoc perlref can get you started with references. perldsc and perllol can walk you through manipulating datastructures built using references. I used map (perldoc -f map) to perform the actual data structure transform. But if you're new to some of this it might be easier to achieve the same thing using a foreach loop (perldoc perlsyn) and push (perldoc -f push):

my @urls;
foreach my $blog ( @{$hash{response}{blogs}} ) {
    push @urls, $blog->{url};
}
[download]

Either way @url ends up containing the same list of URL's.

If you don't mind spending a little on a good book, Intermediate Perl is a great tutorial on references, data-structures, classes, and objects (as well as a few other useful things).

use feature ":5.14";
use warnings FATAL => qw(all);
use strict;
use Data::Dump qw(dump);

my $h = {
          'response' => {
                          'blogs' => [
                                       {
                                         'url' => 'equipo.tumblr.com',
                                         'name' => 'equipo',
                                         'updated' => 1346015230
                                       },
                                       {
                                         'url' => 'linux.tumblr.com',
                                         'name' => 'linuxmint',
                                         'updated' => 1345967468
                                       }
                                     ],
                        }, 
        };

say $_->{url} for @{$h->{response}->{blogs}};
[download]

Produces

equipo.tumblr.com
linux.tumblr.com
[download]

The ->{} ->[] operators can be used to position yourself within the structure and for @{} and for keys %{} can be used to iterate through parts of it.

What about Access and Printing of a HASH OF HASHES?

Simply create a 2-level loop and iterate through the keys of each level.

# untested:
my @urls;
for my $outer ( keys %hash ) {
  for my $inner ( keys %{ $hash{$outer} } ) {
    # maybe check before, if entry "url" exists or is defined ...
    push @urls, $hash{$outer}->{$inner}->{url};
  }
}
[download]

update:

I missed last night that there is an anonymous array inside $hash{$outer}->{$inner}; so here's an updated code:

for my $outer ( keys %hash ) {
    for my $inner ( keys %{ $hash{$outer} } ) {
        push @urls, map { $_->{url} }  @{ $hash{$outer}->{$inner} }
    }
}
[download]

As the other answers point out, if there is only one "outer" and one "inner" key, you can skip the loops and access the inner referenced array directly...