Sorting Hashes of hashes

remluvr has asked for the wisdom of the Perl Monks concerning the following question:

Hi everyone.
My input data are like the following:

$VAR1 = {
          'dove-n' => {
                        'mero' => {
                                    'rump-n' => '0.0986331918077933',
                                    'plume-n' => '0.164895598193776',
                                    'beak-n' => '0.148781820621755',
                                    'head-n' => '0.541972342596793',
                                  },
                        'random-v' => {
                                        'pile-v' => '0.006058551416765
+5',
                                        'kiss-v' => '0.005277682171536
+47',
                                      },
 'cockroach-n' => {
                             'mero' => {
                                         'exoskeleton-n' => '0.0665736
+517016939',
                                         'leg-n' => '0.440277128001941
+',
                                       },
                             'random-v' => {
                                             'suggest-v' => '0.0148588
+863336517',
                                             'guarantee-v' => '0.00591
+007188858908',
                                             'land-v' => '0.0149882471
+117093',
                                           },
[download]

For each keys, I need the entries to be sorted by their score, so for example I'll have something like:

dove-n mero head-n 0.541972342596793
dove-n mero beak-n 0.148781820621755
dove-n mero plume-n 0.164895598193776
dove-n mero rump-n 0.0986331918077933
dove-n random-v pile-v 0.0060585514167655
dove-n random-v kiss-v 0.00527768217153647

cockroach-n mero leg-n 0.440277128001941
cockroach-n random-v suggest-v 0.0665736517016939
cockroach-n mero exoskeleton-n 0.0148588863336517
cockroach-n random-v land-v 0.0149882471117093
cockroach-n random-v guarantee-v 0.00591007188858908
[download]

I've tried reading this: http://perldoc.perl.org/perlfaq4.html#How-do-I-sort-an-array-by-%28anything%29? but I really don't get how I can achieve what I need. Any suggestions?
Thanks,
Giulia

Comment on Sorting Hashes of hashes Select or Download Code

Replies are listed 'Best First'.

Re: Sorting Hashes of hashes
by kcott (Archbishop) on Mar 06, 2012 at 16:28 UTC

Your input data ($VAR1) is an invalid hashref and your example output is not sorted.

After fixing the input and guessing you want highest score first, this code:

#!/usr/bin/env perl

use strict;
use warnings;

my $data = {
    'dove-n' => {
        'mero' => {
            'rump-n' => '0.0986331918077933',
            'plume-n' => '0.164895598193776',
            'beak-n' => '0.148781820621755',
            'head-n' => '0.541972342596793',
        },
        'random-v' => {
            'pile-v' => '0.0060585514167655',
            'kiss-v' => '0.00527768217153647',
        },
    },
    'cockroach-n' => {
        'mero' => {
            'exoskeleton-n' => '0.0665736517016939',
            'leg-n' => '0.440277128001941',
        },
        'random-v' => {
            'suggest-v' => '0.0148588863336517',
            'guarantee-v' => '0.00591007188858908',
            'land-v' => '0.0149882471117093',
        },
    },
};

for my $animal (keys %$data) {
    my @record = ();

    for my $type (keys %{$data->{$animal}}) {
        for my $part (keys %{$data->{$animal}{$type}}) {
            push @record, [$animal, $type, $part, $data->{$animal}{$ty
+pe}{$part}];
        }
    }

    map { print join(q{ } => @$_), qq{\n} } sort { $b->[3] <=> $a->[3]
+ } @record;
}
[download]

produces this output:

dove-n mero head-n 0.541972342596793
dove-n mero plume-n 0.164895598193776
dove-n mero beak-n 0.148781820621755
dove-n mero rump-n 0.0986331918077933
dove-n random-v pile-v 0.0060585514167655
dove-n random-v kiss-v 0.00527768217153647
cockroach-n mero leg-n 0.440277128001941
cockroach-n mero exoskeleton-n 0.0665736517016939
cockroach-n random-v land-v 0.0149882471117093
cockroach-n random-v suggest-v 0.0148588863336517
cockroach-n random-v guarantee-v 0.00591007188858908
[download]

The technique I've used here is to flatten the hash data into individual records and then sort those records.

To reverse the sort order (lowest score first), just swap $a and $b, i.e.

... sort { $a->[3] <=> $b->[3] } ...
[download]

-- Ken

[reply]
[d/l]
[select]

A reply falls below the community's threshold of quality. You may see it by logging in.


Clear questions and runnable code get the best and fastest answer
	PerlMonks