Re: Extracting IP addresses from a file...

foreach($data=~ /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})/g){
    push @ips, $1;
}
[download]

Should do it. (or some re like that.)

$_.=($=+(6<<1));print(chr(my$a=$_));$^H=$_+$_;$_=$^H;
print chr($_-39); # Easy but its ok.
[download]

Comment on Re: Extracting IP addresses from a file... Select or Download Code

Replies are listed 'Best First'.

Re: Re: Extracting IP addresses from a file...
by tachyon (Chancellor) on Jul 05, 2001 at 00:02 UTC

You can't use foreach like this - you need to use while to make your code work. See the code below for a demo:

$data = <<'DATA';
foo 1.1.1.1 foo
bar 22.22.22.22 bar
baz 333.333.333.333 baz
DATA

# this is *wrong*
foreach($data=~ /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})/g){
    push @ips, $1;
}

print "Foreach fails and gives:\n";
print "$_\n" for @ips;

@ips = ();

# this is right
while($data=~ /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})/g){
    push @ips, $1;
}

print "While works and gives:\n";
print "$_\n" for @ips;
[download]

For an explanation of why the for loop generates three copies of the last IP address you need to consider what has happened. A /g type regex will return an array of matches. So as it is called in array context it returns an array (this actually contains the three addresses) however $1 now contains the last address matched as we had to match all occurences to generate the array. We then iterate over this array and push $1 (the last IP address) into our array three times. To fix this we either use while or push $_ (not $1) into our IP array like this:

$data = <<'DATA';
foo 1.1.1.1 foo
bar 22.22.22.22 bar
baz 333.333.333.333 baz
DATA

foreach($data=~ /(\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})/g){
    push @ips, $_;
}

print "Foreach now gives:\n";
print "$_\n" for @ips;
[download]

Oh you can slurp up the file into a variable $data like this:

open FILE, "<path/to/file" or die "Oops, Perl says: $!";
{
    local $/;
    $data = <FILE>;
}
close FILE;
[download]

cheers

tachyon

s&&rsenoyhcatreve&&&s&n\w+t&"$'$`$\"$\&"&ee&&y&srve&&d&&print

[reply]
[d/l]
[select]


"be consistent"
	PerlMonks