Create a hash such as %categories. Iterate over the lines of your list. For each line, split on whitespace, then push @{$categories{$second_column}}, $third_column;

I'm assuming you know how to open a file and read from it. A while loop will be helpful in iterating over each line. Don't forget to chomp.

Output should just be a matter of obtaining the lists held under each hash key and printing them side by side. Another loop with some logic to print a placeholder instead of an item for a given column when one column runs out of entries while others still have entries.

Update: in while loop, changed from split on space to split on tabs because thats how the fields are separated.

#!/usr/bin/perl
use strict;
use warnings;
use Text::Table;
use Sort::Naturally;

my %data;
my @col2 = qw/ PA TT AT /;

while (<DATA>) {
    chomp;
    my ($name, $col2, $col3) = split /\t/;
    push @{ $data{$name}{$col2} }, $col3;
}

my $tb = Text::Table->new( map {title => $_}, @col2);

for my $name (nsort keys %data) {
    my @tmp;
    local $" = ',';
    for my $col2 (@col2) {
        push @tmp, $data{$name}{$col2} ?
            "@{ $data{$name}{$col2} }" :
            "";
    }
    $tb->load(\@tmp);
}

print $tb;

__DATA__
Name_1    TT    XL_927799.1
Name_1    PA    PA_392
Name_1    AT    ZX_003039195.1
Name_2    TT    XL_931313.1
Name_2    AT    ZX_003043016.1
Name_3    TT    XL_929616.1
Name_3    PA    PA_5040
Name_3    PA    PA_6336
Name_4    TT    XL_928294.1
Name_4    PA    PA_917
[download]

This prints:

PA              TT          AT
PA_392          XL_927799.1 ZX_003039195.1
                XL_931313.1 ZX_003043016.1
PA_5040,PA_6336 XL_929616.1
PA_917          XL_928294.1
[download]

Thanks for everybody's suggestions, the solution provided by Cristoforo works brilliantly!