#!/usr/bin/perl

use strict;
use warnings;

use Coro;
use XML::Twig;
use Test::More;
use Perl6::Slurp;
use autodie qw(open);

my $INPUT_A  = "input_A.xml";  # input file A
my $INPUT_B  = "input_B.xml";  # input file B
my $OUTPUT   = "output.xml";
my $EXPECTED = "expected.xml"; # output file C 

open( my $out, '>', $OUTPUT);

my $times; # global, maybe Coro has a better way to pass it around but I don't know it

my $t1= XML::Twig->new( twig_handlers => { elem => \&main_elem }, keep_spaces => 1);
my $t2= XML::Twig->new( twig_handlers => { elem => \&get_times });

# to get the numbers first, before the letters, t2 will be parsed in the main loop          
async { $t1->parsefile( $INPUT_A); };
$t2->parsefile( $INPUT_B); 

print {$out} "\n"; # missing \n for some reason
$t1->flush( $out); 
print {$out} "\n"; # missing \n for some reason

close $out;

is( slurp( $OUTPUT), slurp( $EXPECTED), 'the one test');
done_testing();

sub main_elem
  { my( $t, $elem)= @_;
    $elem->set_text( $elem->text x $times); 
    $t->flush( $out);
    cede;
  }
sub get_times
  { my( $t, $elem)= @_;
    $times= $elem->text;
    $t->purge;
    cede;
  }