Why not just:

while(@arr) {
    my ($x,$y) = (shift(@arr), shift(@arr));
    ...
    }
[download]

Update: ... looks [like] the each generator ...
Maybe (see List::MoreUtils):

use List::MoreUtils qw(natatime);
;;
my $it = natatime 2, @arr;
while (my ($x, $y) = $it->()) {
    ...
    }
[download]

Thanks a lot to you - and all the other ones who replied to my post! I was so focused on the idea having the declaration of my $x and $y inside the loop clause, that I didn't see this obvious solution!
-- 
Ronald Fischer <ynnor@mm.st>

List::MoreUtils has pairwise and natatime, the former which works like a two-at-a-time map and the later makes an iterator that you kick in a while loop.

Example:

    my @x = ('a' .. 'g');
    my $it = natatime 3, @x;
    while (my @vals = $it->())
    {
        print "@vals\n";
    }

This prints

    a b c
    d e f
    g
[download]

How about using splice?

knoppix@Microknoppix:~$ perl -E '
> @arr = ( 1 .. 6 );
> while ( @arr )
> {
>     ( $x, $y ) = splice @arr, 0, 2;
>     say qq{$x - $y};
> }'
1 - 2
3 - 4
5 - 6
knoppix@Microknoppix:~$
[download]

I hope this is helpful.

Have you tried using each itself. as in something like ...

my $array = { @array };
while (my ($k, $v) = each %$array) {
  .
  .
}
[download]

my $array = { @array };
[download]

This will 'randomize' (or 'hash-ize'?) the order of elements in the array, and  %{{@array}} likewise. Update: Oops:  each %{{@arr}} has another, entirely different, fatal (or should I say immortal?) flaw!

I suppose that depends on whether the pairs have to pulled from the list in the same order in which they appear in the list ... which altho' implied, isn't, AFAICT, specified in/by the OP.

Ooops, my mistake, it _is_ specified : 'This array should be processed left-to-right...'

A user level that continues to overstate my experience :-))

Have you tried using each itself.

This doesn't work, because this would require $array being a hash reference.
-- 
Ronald Fischer <ynnor@mm.st>

Interestingly, the 5.12+ each allows iteration over an array (and similarly for keys and values), but each 'key' is a succcessive index of the array, and each 'value' is the element at that index: not quite what you wanted in the OP.

>perl -wMstrict -le
"my @ra = qw(a b c d);
 ;;
 while (my ($i, $element) = each @ra) {
   print qq{ra $i is '$element'};
   }
"
ra 0 is 'a'
ra 1 is 'b'
ra 2 is 'c'
ra 3 is 'd'
[download]

I'd normally use a slightly simpler version of JohnGG's splice approach. Something like

my @arr = qw/1 2 3 4 5 6 7 8/;
while(my ($x,$y) = splice @arr,0,2) {
  say "$x => $y";
}
[download]

Something I've needed in the past was to get two arrays (odds and evens). Grep can do this. You could combine them into a hash thus:

my @arr = qw/1 2 3 4 5 6 7 8/;

my ($j,$i)=(0,0);
my ($x,$y) = ([grep { ++$i % 2} @arr] , [grep {$j++ % 2} @arr]);
my %hash;
@hash{@{$x}}=@{$y};

for(keys %hash) {
  say "$_ => $hash{$_}"
}
[download]

1 => 2
3 => 4
7 => 8
5 => 6
[download]

my @arr = qw/1 2 3 4 5 6 7 8/;
push @arr, undef;
push @arr, 9;


my ($j,$i)=(0,0);
my ($x,$y) = ([grep { ++$i % 2} @arr] , [grep {$j++ % 2} @arr]);
$i=0;
for(@{$x}){
  say $_ ." => " . $y->[$i++] if($_);
}
[download]

Something I've needed in the past was to get two arrays (odds and evens).

You can also push onto two arrays using a ternary.

knoppix@Microknoppix:~$ perl -E '
> push @{ $_ % 2 ? \ @odds : \ @evens }, $_ for 1 .. 8;
> say qq{ Odds : @odds};
> say qq{Evens : @evens};'
 Odds : 1 3 5 7
Evens : 2 4 6 8
knoppix@Microknoppix:~$
[download]

I hope this is of interest.

Cheers,

JohnGG

List::MoreUtils also has  part to do similar things:

>perl -wMstrict -le
"use List::MoreUtils qw(part);
 use Data::Dumper;
 ;;
 my $i;
 my @parts = part { ++$i % 2 } 1 .. 8;
 ;;
 print Dumper \@parts;
"
$VAR1 = [
          [
            2,
            4,
            6,
            8
          ],
          [
            1,
            3,
            5,
            7
          ]
        ];
[download]

Pick a way that works, make it clear as a bell, add a comment and move on...