Variable "%data" is not available

Hue-Bond has asked for the wisdom of the Perl Monks concerning the following question:

Monks,

I'm finding the uncommon error Variable "%data" is not available when using the following module:

package Foo;

use warnings;
use strict;

my %data = qw/foo bar/;

our $AUTOLOAD;
sub AUTOLOAD {
    my ($self, @args) = @_;
    my ($pkg, $field) = (__PACKAGE__, $AUTOLOAD);
    $field =~ s/${pkg}:://;

    ## uncommenting any of these, makes the code work
    #%data;
    #() = %data;
    #map $_, %data;
    #map $_, \%data;
    #$::qwerty123 = %data;

    eval "*$field = sub { return \\%$field; };";
    $@ and die "eval failed: $@\n";

    goto &$field;
}

1;
[download]

$ perl -I. -MData::Dumper -MFoo -e'print Dumper (Foo->data)'
Variable "%data" is not available at (eval 1) line 1.
$VAR1 = {};
[download]

As a workaround, it's enough to uncomment any of the commented lines (although the first of them triggers the expected warning):

$ perl -I. -MData::Dumper -MFoo -e'print Dumper (Foo->data)'
Useless use of private hash in void context at Foo.pm line 16.
$VAR1 = {
          'foo' => 'bar'
        };
[download]

At this point I checked perldiag, which says: "This can happen for one of two reasons. First, the outer lexical may be declared in an outer anonymous subroutine that has not yet been created. [...] The second situation is caused by an eval accessing a variable that has gone out of scope".

To me, this scenario isn't covered by either of the given explanations. I could be led to believe that the first of the reasons explains it, although then I'd like to be educated on how this module compares to an anonymous subroutine regarding the compilation-time vs run-time issues that are detailed in the documentation and result in this error.

Just for fun, I appended the following at the bottom of Foo.pm:

package main;
use warnings;
use strict;
use Data::Dumper;
print Dumper (Foo->data);
[download]

Then, running perl Foo.pm works fine even with all those 5 lines mentioned above commented out.

--
David Serrano
(Please treat my english text just like Perl code, i.e. feel free to notify me of any syntax, grammar, style and/or spelling errors. Thank you!).

Comment on Variable "%data" is not available Select or Download Code

Replies are listed 'Best First'.

Re: Variable "%data" is not available
by ikegami (Pope) on Mar 21, 2011 at 20:53 UTC

To me, this scenario isn't covered by either of the given explanations.

It's covered by the second one. %data has gone out of scope. The lexical block in which it resides (the file) was exited before AUTOLOAD was called.

A sub can extend the life of a lexical by becoming a closure and capturing the lexical. However, a sub only captures the variables it needs, meaning it only captures the lexicals it references. Other lexicals aren't captured.

If there's a reference to (i.e. a mention of) %data in AUTOLOAD (e.g. if you uncomment any of the commented statements), then the sub captures %data, and the eval will find %data.

If there are no references to %data in AUTOLOAD, then the sub doesn't capture %data, so it won't exist when eval is evaluated.

Adding «%data if 0;» to AUTOLOAD is enough to make it capture the lexical without warnings.

$ perl -wE'{ my $s=1; sub f {          eval q{$s} } } say f || 0;'
Variable "$s" is not available at (eval 1) line 2.
0

$ perl -wE'{ my $s=1; sub f { $s if 0; eval q{$s} } } say f || 0;'
1
[download]

Another option is to use a package variable since they don't go out of scope.

$ perl -wE'{ my  $s=1; sub f { eval q{$s} } } say f || 0;'
Variable "$s" is not available at (eval 1) line 2.
0

$ perl -wE'{ our $s=1; sub f { eval q{$s} } } say f || 0;'
1
[download]

Then, running perl Foo.pm works fine

I cringe whenever someone does

perl -c Foo.pm
[download]

perl -e'use Foo;'
[download]

because they're not equivalent. The crucial difference in this case is that you now call AUTOLOAD before the lexical scope of %data is exited.

[reply]
[d/l]
[select]


XP is just a number
	PerlMonks