What you need to do is use a die handler. Here's a complete program that logs errors to a file:

#!/opt/perl/bin/perl

use warnings 'all';
use strict;

{   my ($fh, $logfile);

    INIT {
        $logfile = "/var/log/whatever/errors";
        open $fh => ">> $logfile" or die "Failed to open $logfile: $!\
+n";
        $SIG {__DIE__} = sub {
            print $fh @_;
            print $fh "\n" unless $_ [-1] =~ /\n\z/;
        };
    }

    END {
        $fh and (close $fh or warn "Failed to close $logfile: $!\n");
    }
}

print "Hello, world\n";
die "Meep, meep!";
print "I should be dead....\n";
__END__
[download]

-- Abigail

I personally would opt for the most straight forward way: Create a sub that logs the results to a file, and then call die.

    # excuse the sloppy code...
    sub log_and_die
    {
          my $msg = shift;
          # suppose $fh is an already defined, opened
          # file handle. of course, you can open one here
          # as well...
          print $fh $msg;
          die $msg;
    }

    DBI->connect( ... ) || log_and_die( $! )
[download]

local $SIG{__DIE__} = sub {

  # get error message
  my $err = $_[0];

  # open error log or exit - you can't die here :)
  open(ERRLOG,'>>/path/to/errlog') || exit(0);

  # you may want to add information from the caller()
  # function here and add other info to log

  print ERRLOG "Error: $err\nplus whatever else you need...\n\n";
  close(ERRLOG);
  exit(0);
}
[download]

cLive ;-)

As for a way to make all dies go to a logfile, reopening STDERR to somewhere else at the beginning of the script could help you:

open STDERR, ">errors.log" or 
  warn "failed to reopen STDERR: $!\n";
[download]

(updated because "actual problem" was the wrong phrase where I used it.)

Most posts in this thread concentrate on how to catch the error message, but I don't think that's the real issue. wog's message touches on it. The eval should put the database handle somewhere so that a cleanup routine can deal with it in case there's an error. You might try something like this:

eval {
  my $dbh = DBI->connect(..., {RaiseError=>1});
  eval {
    $dbh->do("update ...");
    $dbh->do("update ...");
  };
  if ($@) {
    # clean up after an unsuccessful update
    $dbh->rollback();
    $dbh->disconnect();
    die($@);  # reraise the error
  }
  # successful update
  $dbh->commit();
  $dbh->disconnect();
};
if ($@) {
  log($@);
}
[download]

DBI->connect() or print LOG "Error message\n";
[download]

Is that what you need?

Russ
Brainbench 'Most Valuable Professional' for Perl

BEGIN {
     use CGI::Carp qw(carpout);
     open(LOG, ">>/path/to/my/log") or
       die("Unable to open log: $!\n");
     carpout(LOG);
   }
[download]