You don't say what to do if the match is found in the first five lines of the file. I'm going to assume that this can't happen. I'm also going to assume that you don't want to read the whole file into memory at once.

I'd build a buffer that always contains the previous five lines and work with that. Something like this:

#!/usr/bin/perl -w

use strict;

my @buffer;

push @buffer, scalar <DATA> for 1 .. 5;

my $pat = 8; # adjust to value to search for
while (<DATA>) {
  print $buffer[0] if /$pat/;

  push @buffer, $_;
  shift @buffer;
}

__END__
1
2
3
4
5
6
7
8
9
10
[download]

Perl Training in the UK <http://www.iterative-software.com>

Nice. One suggestion:

# change:
print $buffer[0] if /$pat/;

# to:
print $buffer[0] if /\Q$pat\E/o;
[download]

The \Q and \E presume that $pat is just a string, not a regex. So you would want to escape any special characters (like '.' or '+' ) and the o tells Perl that $pat isn't going to change in the loop, so it won't keep recompiling the pattern.

Try this:

my @previous;
while (<LINE>) {
    if ($_ eq "STRING TO COMPARE WITH\n") {
        print $previous[0];
        last;
    }
    push @previous, $_;
    shift @previous if @previous > 5;
}
[download]

Update: Thanks to jeroenes for spotting a couple of things that could be done better - I've incorporated your suggestions into the code.

Update 2: Thanks to davorg for noticing that print @previous prints out all of the last 5 lines, but pat asked for the line 5 lines previous to the one being searched. I've changed the print @previous line to read print $previous[0] instead.

This is a very elegant solution, ++

tachyon

if the file isn't big, read it all in an array, then when you find your match, save your location, and retrieve it directly from the array..

Update:Here it is, completely untested for bugs:

# assuming the file is already opened and has a <IN> filehandle

my @temp;

# and assuming that you won't match before the first 5 lines..

while (my $line = <IN>) {
    push @temp, $line;
    shift @temp if (scalar @temp > 5);
    if ($line =~ /foo/) { 
        # we've got a match.
        print $temp[0];
    }
}
[download]

Update 2: This looks like davorg's more elegant solution.

open X,"<$file";
@rows = <X>;
close X;

for($i=0;$i<$#rows;$i++)
{
        if($rows[$i] =~ /something/) {
                print $rows[$i-5];
        }
}
[download]

Why read in the whole file when you're only ever interested in five lines? Sounds a bit wasteful of memory to me :)

--
<http://www.dave.org.uk>

Perl Training in the UK <http://www.iterative-software.com>

(I cleared this post. Note to self: never post when hungover)

Update:I agree, it's wasteful

when I was opening the file it would not open as you had written above so I changed to open (X, $inputfile); and it opened fine and did what it was meant to do thanks but i have seen this before where the syntax you used to open the file did not work, have you seen this and any idea why it is so thanks once again! Pat ( go raibh mile maith agat)

If file is really huge, you do not want to read whole file into memory.

davorg rules!

pmas