note
liverpole
Well, I may have solved my own problem.
</p><p>After reading through the documentation some more, I found the <c>Open</c> method:
<c>
$subKey= $key->Open( $sSubKey, $rhOptions )
The Open method opens a Registry key and returns a new Win32::TieRegistry
object associated with that Registry key. If Open is called via a reference to
a tied hash, then Open returns another reference to a tied hash. Otherwise Open
returns a simple object and you should then use TiedRef to get a reference to a
tied hash.
$sSubKey is a string specifying a subkey to be opened. Alternately $sSubKey
can be a reference to an array value containing the list of increasingly deep
subkeys specifying the path to the subkey to be opened.
...
</c>
</p><p>Which seems to do the trick in my modified program:
<c>
#!/usr/bin/perl -w
#
# Attempt to delete 'HKEY_CLASSES_ROOT/Folder/shell/xyzzy_1' from the
# Windows Registry, using Win32::TieRegistry.
#
# This version uses the 'Open' method -- Success!
##
#############
# Libraries #
#############
use strict;
use warnings;
use Data::Dumper;
use Win32::TieRegistry( Delimiter => '/' );
################
# Main Program #
################
# Step 1 -- assign to the 'Folder' key
my $label = "xyzzy_1";
my $key = 'HKEY_CLASSES_ROOT/Folder';
my $h_folder = $Registry->{$key};
(defined $h_folder) or die "Unable to find registry key '$key'\n";
# Step 2 -- open at the 'shell' subkey
my $h_shell = $h_folder->Open('shell', { 'Delimiter' => '/' });
$h_shell or die "Unable to open subkey 'shell' (of key '$key')\n";
# Step 3 -- Display values for the 'shell' subkey
print "[Values for '$key/shell']\n";
my $idx = 0;
foreach my $key (keys %$h_shell) {
printf " %3d. %s\n", ++$idx, $key;
}
print "\n\n";
# Step 4 -- Validate that the label 'xyzzy_1' was found
if (!exists($h_shell->{"$label/"})) {
die "No such label for '$key' => '$label'\n";
}
# Step 5 -- Delete 'xyzzy_1' from the 'shell' subkey
print "Deleting label '$label' ...\n";
my $result = delete($h_shell->{"$label/"});
printf "Result of delete: '%s'\n", Dumper($result);
</c>
</p><p>One caveat is that, if the <c>regedit</c> program is open, you must refresh its state after the delete (View > Refresh or function key F5), otherwise the display will continue to show the deleted key (eg. 'xyzzy_1'), but clicking on it (and other operations) will give a regedit error.
<div class="pmsig"><div class="pmsig-465654">
<hr />
<font size="1">
s''(q.S:$/9=(T1';s;(..)(..);$..=substr+crypt($1,$2),2,3;eg;print$..$/
</font>
</div></div>
858245
858245