sanju7:

I downloaded your code so I could study it in more detail. Here are some things I noticed:

• You commented out use strict;. Usually, if commenting that out ever changes anything in your code, you should try to fix the offending line rather than suppressing the error message. In this case, uncommenting use strict didn't make any difference.
• The $Error variable never changes, so I removed code that's never executed.
• I found the indentation a bit confusing, so I reformatted the code a bit.
• I moved the definition of sub wanted to the end (it was visually distracting to me).
• I didn't want to arbitrarily remove files on my system, so I changed the rmdir statement to a print statement.
• You're setting the values of $ThisMoveTarget and $ThisSourceDirectory in your code and not changing them, so I didn't see a need to test their values, so I removed those tests. (Obviously you'll want to keep the tests if you get the values from user input.)

At this point, I had:

#! /usr/bin/perl -w
use strict;
use diagnostics;
use File::Find;

# Variable "ThisMoveTarget" contains destination archive location
# path. If this stores a path (i.e if directories are archived)
# then the main body of code (i.e walk down the source location
# for deleting empty directories) should execute
# my $ThisMoveTarget = q|holds location where archive files
# should go |;
my $ThisMoveTarget = '/home/ssaha/tmp/archive';

# our $DelEmptyFoldrArchive = q|holds yes or no |;
our $DelEmptyFoldrArchive = "yes ";

# our $ThisSourceDirectory = q|holds the source file location |;
our $ThisSourceDirectory = "/home/ssaha/tmp/source/";
#our $ThisSourceDirectory = "\\\\hostname\\share-test";

my $file ;
if ($DelEmptyFoldrArchive eq "yes ") {
   print STDERR "Debug3: entering check1 \n" ;
   find({ wanted => \&wanted, no_chdir => 1 }, $ThisSourceDirectory);

   if ($file) {
      print STDERR "Debug3: entering check2 file is file \n" ;
      print STDERR "The $ThisSourceDirectory has files present \n" ;
   }
   elsif (!$file) {
      print STDERR "Debug3 entering check3 file is no file\n" ;
      finddepth (sub { print "rmdir $_\n"; }, $ThisSourceDirectory);
   }
}
else {
   print STDERR "Debug3: entering check5 \n" ;
   print STDERR "DelEmptyFoldrArchive is $DelEmptyFoldrArchive, skippi
+ng directory deletion. \n" ;
}

sub wanted {
   return unless -f;
   $file = $_;
   print STDERR "$file \n " ;
}
[download]

At this point, the code is pretty clear, and one of the errors is apparent: Some of the code you probably intended to be in the wanted subroutine was actually following it, so it only checked the last file found at that part. The my $file; declaration was at the outermost scope, and hid that from you. By moving the declaration inside of sub wanted (along with the associated code), it cleans things up a bit more.

I stopped at this point for now, so you can work a little more on it.

Another note: perl works well with forward slashes in paths, even under Windows. You may find it helpful (as I do) to always use forward slashes in paths. It helps portability and you can avoid the headache of quoting backslashes.

...roboticus

Roboticus:

Thanks for your valuable input.

About forward slashes: I just included the part of my code which was accidentally excluded. I am dealing with user input and most times its two backslashes forwarded by server name and share (\\hostname\share-dir\ ).

Also i think the area where the thing going wrong at Linux environment is the rmdir $_ is feeding the directory name only and not the full path with the name.

I am getting script output like below, i added a print statement inside "findpath" like below, print " directories are $_ \n";

 directories are folder
 directories are dir2
 directories are folder
 directories are dir3
 directories are folder
 directories are dir1
 directories are .
[download]

How can i make sure the find path function returns full path for every empty directory?

sanju7:

The documentation for the wanted function interface for File::Find shows that it uses three variables to communicate with the function:

• $File::Find::dir is the current directory name,
• $_ is the current filename within that directory, and
• $File::Find::name is the complete pathname to the file.

So just use $File::Find::name instead of $_ to get the complete path name.

...roboticus