Is there any way I can perform the above?

Not particularly efficient, but possible:

$s = '1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15';;

print for grep length, split /(\S+\s+\S+\s+\S+)\s+/, $s;;
1 AC2 34
TRP A 6
ALA A 7
ILE A 14
GLY A 15
[download]

perl -E 'say for split /\S+\s+\S+\s+\S+\K\s+/, "1 2 3 4 5 6 7 8 9"'
[download]

perl -E 'say for split /(?:\S+\K\s+){3}/, "1 2 3 4 5 6 7 8 9"'
[download]

perl -E 'say for split /\S+\s+\S+\s+\S+\K\s+/, "1 2 3 4 5 6 7 8 9"'

Neat!++ It never crossed my mind that /K would work with split.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

RIP an inspiration; A true Folk's Guy

As a newbie I'm reading and deciphering your response. My reference material doesn't seem to mention "K" anywhere. Can you (or anyone) enlighten me?

http://search.cpan.org/~jesse/perl-5.12.0/pod/perlre.pod

    \K       Keep the stuff left of the \K, don't include it in $&
[download]

use strict;
use warnings;
use List::MoreUtils qw(natatime);

my $line = '1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15';
my @tokens = split /\s+/, $line;
my $it = natatime(3, @tokens);
while (my @vals = $it->()) {
    print "@vals\n";
}
[download]

Another way just using a global match with an alternation of look-behinds rather than split.

$ perl -E '
$_ = q{1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15};
say for m{(?: (?<=\A) | (?<=\s) )( (?:\S+\s+){2} \S+ ) }gx;'
1 AC2 34
TRP A 6
ALA A 7
ILE A 14
GLY A 15
$
[download]

I hope this is useful.

#!/usr/bin/perl
use strict;
use warnings;

$_ = '1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15';

print join "\n", /\S+(?: \S+){1,2}/g;
[download]

print "$1\n" while /(\S+(?:\s+\S+){0,2})/g;

Yet another way using split on spaces but with a capture so the spaces are retained. Discard every 6th element then join five at a time.

$ perl -E '
> $_ = q{1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15};
> @e = grep { ( ++ $i ) % 6 } split m{(\s+)};
> say join q{}, map { shift @e } 1 .. 5 while @e;'
1 AC2 34
TRP A 6
ALA A 7
ILE A 14
GLY A 15
$
[download]

And Another One Way

$name=qq(1 AC2 34 TRP A 6 ALA A 7 ILE A 14 GLY A 15);

split (/ /, $name);

### Process the temp array
for ( $i=0; $i<=$#_; $i++)
{
    push @get, (join ' ', @_[$i..$i+2]);
    $i=$i+2;
}

print "\n$_" for @get;
[download]

While this code does produce correct results in this case, you are ignoring a warning message because you do not use strict and warnings:

Use of implicit split to @_ is deprecated
[download]

$ perl -le 'use strict;use warnings;my($s,@r,@t) = "1 AC2 34 TRP A 6 A
+LA A 7 ILE A 14 GLY A 15";@t=split/\s+/,$s;while((@r=splice @t,0,3)==
+3){print join(" ",@r);}warn"leftovers: @r\n"if @r;'
1 AC2 34
TRP A 6
ALA A 7
ILE A 14
GLY A 15
[download]