I use $SIG{__DIE__} to send me a mail:

$SIG{__DIE__} = sub {
    my $err = $@;
    local $@;
    mail($@);
};
[download]

That way, whenever the script dies, the error gets mailed to me.

I think the die-message is available in $@ only in case the die happens within an eval{} block (in which case I personally wouldn't want to be mailed).

If the die happens outside of an eval, however (i.e. when the script atually dies), the message is only available in @_.   (Also, I suppose your code should be mail($err), as the localized $@ would always be empty...)

In other words, I'd use something like

#!/usr/bin/perl

use strict;
use warnings;
use Carp;

$SIG{__DIE__} = sub {
    die @_ if $^S;   # skip handler for eval{} blocks
    mail(@_);
};

sub mail {
    chomp(my $msg = shift);
    print qq(mailing "$msg"...\n\n);
}

sub test {
    eval { croak "bar"; };  # doesn't send mail
    croak "foo";            # sends mail (and dies)
}

test();

__END__
$ ./827866.pl
mailing "foo at ./827866.pl line 19
        main::test() called at ./827866.pl line 22"...

foo at ./827866.pl line 19
        main::test() called at ./827866.pl line 22
[download]

http://perldoc.perl.org/functions/caller.html

#!/usr/bin/perl
exit main();

sub main
{
    print_error("test1");
    print_error("test2");
    print_error("test3");
    return 0;
}

sub print_error
{
    my ($error) = @_;
    my $line = (caller(0))[2];
    print "line " , $line , ": " , $error , "\n";
}
[download]

This will print:

-bash:perl$ perl caller.pl
line 6: test1
line 7: test2
line 8: test3
[download]

but I can't figure out how to redirect the carp output

Carp provides a routine shortmess, which just returns the string that carp would write to STDERR.  So you could say

my $error;
opendir(DIR, $dir) or $error = Carp::shortmess("Could not open $dir");

mail($error) and die $error if $error;
[download]

I have no idea, though, why shortmess is no longer documented in 5.10.x (in 5.8.8 it was), despite the fact that it's still there and works...

Actually, the implementation of carp is just sub carp { warn shortmess @_ }. And shortmess is also in @EXPORT_OK.

P.S.:  Does anyone know if it has been deprecated (nothing related is mentioned in either the 5.10 or the 5.8 docs), or what else might be wrong with using it?

I have no idea, though, why shortmess is no longer documented in 5.10.x (in 5.8.8 it was), despite the fact that it's still there and works... P.S.: Does anyone know if it has been deprecated (nothing related is mentioned in either the 5.10 or the 5.8 docs), or what else might be wrong with using it?

I do not know of anything wrong with shortmess. A quick glance at delta docs does not reveal anything. I recommend you submit a patch to add this back into the POD using perlbug. Either it will be fixed, or you should get a response explaining why it will not be fixed.

I have been planning to submit a patch for a minor POD bug in Carp, but I have been too Lazy.

Perhaps I'm missing something, but cron will mail a program's output to the owner's account. Just make sure you have the job owner's account correctly configured or in the 'aliases' file.

Perhaps not a glamorous perl solution, but it keeps the arcane out of your scripts.

If your script's STDOUT is already being mailed to a user other than you, have the cron job redirect it's STDERR to your mail.

I do not like the fact that the line number is static and I have to remember to update it if I ever modify the script (I won't remember).

Use __LINE__ for that:

use warnings;
use strict;

printf "I'm in line %d\n", __LINE__;
printf "I'm in line %d\n", __LINE__;
printf "I'm in line %d\n", __LINE__;
__END__
I'm in line 4
I'm in line 5
I'm in line 6
[download]