If you use a hash to hold different sort functions, then you can call that function from inside the sort block. There are probably better ways to do this, but this works.

#!/usr/bin/perl
use strict;
use warnings;



my $test = shift;

my $sort = {
    'numbers' => sub { $_[0] <=> $_[1] },
    'letters' => sub { "$_[0]" cmp "$_[1]" },
};

my @test = qw/1 2 3 4 a b 0 10 9 100/;

print sort {$sort->{$test}->($a,$b)} @test;
[download]

If you run this perl sort_test.pl letters it will use the cmp and if you run perl sort_test.pl numbers it will sort using <=>

my $sort = { };? my %sort = ( );!

I tend to use references always, dunno why, habit i suppose. I like the way they look?


___________
Eric Hodges

What's wrong with the simple solution?

my @sorted;
if ($joe eq "numbers") {
     @sorted = sort { 
         $hoh{$a}->{value} <=> $hoh{$b}->{value} 
     } keys %hoa;
}
else {
     @sorted = sort { 
        $hoh{$a}->{value} cmp $hoh{$b}->{value} 
     } keys %hoa
}

foreach $key ( @sorted ) {
    blah;
}
[download]

Not quite as fancy as Eric's version, but should get the job done, too:

#!/usr/bin/perl
use strict;
use warnings;

my %hoh = (
    bar => {value => 42},
    baz => {value => 199},
    foo => {value => 3},
);

my $joe = shift @ARGV;

my $sortfunctions = {
    numbers => sub { $hoh{$a}{value} <=> $hoh{$b}{value} },
    letters => sub { $hoh{$a}{value} cmp $hoh{$b}{value} },
};
my $sortfunc = $sortfunctions->{$joe};

foreach my $key (sort $sortfunc keys %hoh) {
    print "$key: $hoh{$key}{value}\n";
}

__END__
$ ./818578.pl letters
baz: 199
foo: 3
bar: 42
$ ./818578.pl numbers
foo: 3
bar: 42
baz: 199
[download]