my $i;
for (values %hoh) {
    $_->{age} == 12 && $i++;
}
[download]

PS: ah, you want to do it "without looping through each hash and counting." No, I don't think that's possible.

rethaew want[s] to do it "without looping through each hash and counting." No, I don't think that's possible.

I agree. Even a solution like
    my $age12 = grep $_->{age} == 12, values %hoh;
implicitly loops through the hash. rethaew will have to wait for the arrival of the personal desktop quantum computer to solve the problem without looping.

This really begs for an "RTFM" answer. Have you done so?

If that hasn't (doesn't) make it clear to you, then Data Type: Hash should help (special attention to the content and links in planetscape's offering).

In either case, you really need to show that you've made some effort to find your own answer to the problem: where's the code for what you've tried so far and how does it fail? See, please, On asking for helpand How do I post a question effectively?.

$ages{$_->{'age'}}++ foreach values %hoh;
[download]

{ 11 => 2, 12 => 2, 13 => 1 }
[download]

use warnings;
use strict;

my %hoh = (
 kevin => {
   age   => "12",
   favorite_color       => "blue",
   gender       => "boy",
 },
 john => {
   age   => "11",
   favorite_color       => "green",
   gender       => "boy",
 },
 lisa => {
   age   => "11",
   favorite_color       => "pink",
   gender       => "girl",
 },
 sara => {
   age   => "13",
   favorite_color       => "purple",
   gender       => "girl",
 },
 shelly => {
   age   => "12",
   favorite_color       => "purple",
   gender       => "girl",
 },
);

my $num_12 = grep { $_ == 12 } map { $hoh{$_}->{'age'} } keys %hoh;

my $num_alt = grep { $hoh{$_}->{'age'} == 12 } keys %hoh;

print "Num 12: $num_12\n";
print "Num 12 alt: $num_alt\n";
[download]

Improving on your idea:

print scalar grep{$_->{'age'} == 12} values %hoh;
[download]

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

I like yours better.

my %counts=();
foreach $kid (%hoh) {
  foreach my $attribute (%$kid) {
    $counts{$attribute}{$kid->{attribute})++;
  }
}

...
print $counts{'age'}{12};
[download]

Sadly this "one-time" cost has to be paid whenever the data changes (unless you also adjust the counts in the second HoH whenever you change anything)

UPDATE: Fixed the bug in the first line thanks to warnings from johngg and chromatic. It was too much to hope that I could write even a 4-liner without a trivial bug.

my %counts={};

I think you need parentheses rather than curlies there. As it is, you are assigning a single hash reference to the hash, which it will then stringify and use as a key with no corresponding value. Also, if you use warnings;, I think you will get one complaining about odd number of elements in hash assignment, or words to that effect. Trying it I get this.

$ perl -MData::Dumper -Mstrict -wle '
> my %h = {};'
> print Data::Dumper->Dump( [ \ %h ], [ qw{ *h } ] );'
Reference found where even-sized list expected at -e line 2.
%h = (
       'HASH(0x817f880)' => undef
     );
$
[download]

I hope this is useful.

Cheers,

JohnGG

However, if what you want to know is how many people are of age 12, as per your example, you have to collect to data by key. Since this means you need to look at each entry, how would you expect to not have to examine each node in a loop? You can use built-ins like map to reduce the total number of characters, but will likely make the code more difficult to read in the future. The clearest way to determine how many people are 12 would be to loop over the hash and collect counts in a hash:

#!/usr/bin/perl
use strict;
use warnings;

my %hoh = (
 kevin => {
   age   => "12",
   favorite_color       => "blue",
   gender       => "boy",
 },
 john => {
   age   => "11",
   favorite_color       => "green",
   gender       => "boy",
 },
 lisa => {
   age   => "11",
   favorite_color       => "pink",
   gender       => "girl",
 },
 sara => {
   age   => "13",
   favorite_color       => "purple",
   gender       => "girl",
 },
 shelly => {
   age   => "12",
   favorite_color       => "purple",
   gender       => "girl",
 },
);
my %counts;
my $key = 'age';
foreach my $person (values %hoh) {
    $counts{$person->{$key}}++;
}
use Data::Dumper;
print Dumper(\%counts);
[download]