note
blokhead
<blockquote><i>I think the first step would be to split ranges which overlap other ranges into separate non-overlapping ranges: </i></blockquote>
Why do you need to split them into non-overlapping segments before doing $hash{$item}++ ?
<p>
Also, are you absolutely sure that iterating over the elements will really be a bottleneck? It seems likely that you won't be able to gain much efficiency since the obvious algorithm is so simple. Anyway, here is a sparser way to represent this problem:
<p>
You can represent the set of ranges by just keeping track of places where the # of intervals changes, so that
<code>
00112233222000
</code>
becomes
<code>
(3,1), (5,2), (7,3), (9,2), (12,0)
</code>
In other words, if (i,j), (m,n) are adjacent in this list, then there are j ranges that cover element i to element m-1. This list is sparse, and its size only depends on the number of ranges, not the number of their elements.
<p>
To query this list on a number (to see how many ranges cover a point x), you can do a binary search to find the largest number < x in the list. That entry in the list will tell you how many ranges cover x.
<p>
To construct the list, you can do $delta{$start}++, $delta{$end}--, for every ($start,$end) interval (I chose a hash because it can stay sparse if the intervals are large). Then you can iterate through the sorted keys of %delta and make a running total.
<code>
my @intervals = ([3,11], [5,8], [7,11]);
for (@intervals) {
my ($start,$end) = @$_;
$delta{$start}++;
$delta{$end+1}--;
}
my $total = 0;
my @points;
for (sort { $a <=> $b } keys %delta) {
next if $delta{$_} == 0; ## update: added this line
$total += $delta{$_};
push @points, [$_, $total];
}
</code>
<p>
Again, this is much more efficient in the theoretical sense (to generate the data structure takes O(n log n), where n is the # of intervals, compared to O(nt) where t is the average size of an interval), but maybe not much of a gain for you depending on the actual sizes of things involved (and depending on what kind of queries you want to make to the data structure). Querying the data structure is a tradeoff, it is now O(log n) instead of constant had you gone the route of iterating through all the elements of the intervals.
<!-- Node text goes above. Div tags should contain sig only -->
<div class="pmsig"><div class="pmsig-137386">
<p>
blokhead
</div></div>
796962
796962