I would like to know what it is about my pattern that creates all those undefs

The match operator returns the value captured by each capture. The following has two captures:

/(?: (\d+) | (?:"(.+?)")  ) /gx
     ^           ^
     |           |
[download]

so two values are returned for each match. Given the pattern, one will always be undef since one will always be outside the path that matched.

It's not evident from your code that it would be a problem to only return one value because you treat both values equally. In real life, you almost always want to treat the two kinds of matches differently. For example,

sub dequote {
    my ($s) = @_;
    $s =~ s/\\(.)/$1/g;
    return $s;
}

push @matches, defined($1) ? $1 : dequote($2)
   while /(?: (\d+) | (?:"(.+?)")  ) /gx;
[download]

If the pattern only returned one value, you wouldn't be able to tell which part of the pattern matched, so you couldn't take decisions based on that (such as whether to call dequote or not).

The /g modifier specifies global pattern matching--that is, matching a
+s many times as possible within the string. How it behaves depends on
+ the context. In list context, it returns a list of the substrings ma
+tched by any capturing parentheses in the regular expression. If ther
+e are no parentheses, it returns a list of all the matched strings, a
+s if there were parentheses around the whole pattern.
[download]

Much better, IMO, to grep for only defined values (single-quotes used in example instead of double-quotes to avoid lots of escaping on XP command line):

>perl -wMstrict -MData::Dumper -le
"my $str = q{1,2,3,4,'fine', '', 'day','today',};
 my @f =
   grep defined,
   $str =~ m{ (\d+) | ' ([^']*) ' }xmsg
   ;
 print Dumper \@f;
"
$VAR1 = [
          '1',
          '2',
          '3',
          '4',
          'fine',
          '',
          'day',
          'today'
        ];
[download]

I would like to know what it is about my pattern that creates all those undefs

Your pattern   (\d+) | (?:"(.+?)") has two groups of capturing parentheses so when one group matches the other returns undef and vice-versa.

#!/usr/bin/perl -w
use strict;
use Data::Dumper;

my $s = '1,2,3,4,"fine",,,"day","today",,,';

$s =~ s/['"]//g;   #no quotes

my @s = split(/,/,$s);

print Dumper \@s;
__END__
$VAR1 = [
          '1',
          '2',
          '3',
          '4',
          'fine',
          '',
          '',
          'day',
          'today'
        ];
[download]

I know that you're inquiring about matching regex's, but if all you want to do is to remove the double-quotes, you could, I think and IMHO, use the substitution regex approach as I did in the code below.

#!/usr/bin/perl

use warnings;
use strict;

my $string = '1,2,3,4,"fine","day","today"';

print "\$string = [ $string ]\n";
print "\n";

$string =~ s/\"//gx;
    
print "\$string = [ $string ]\n";
   
exit(0);
[download]

I tried several variations using the match regex approach and couldn't get one to work. I'm sure there is a way; I just couldn't easily construct one. I'm barely regex-literate, though, so the various responses are interesting to me and have already tought me a lot that I didn't know.

Yet another solution ;) Just remove the quotes after you do your splitting.

@b = map { s/\"//g; $_ } @a;
[download]