You should look at Moose. It's better OOP. If you're in a hurry you can also check out Class::Accessor which is passable but nowhere near as rich as Moose.

Listen to Your Mother.

I thought you might be curious about the specifics of how the advice to use Moose would help in this case, though. The functionality of your code above would be replaced by:

package Whatever;
use Moose;

has 'main_message' => ( is => 'rw' );
[download]

Poof! Instant access to $whatever->main_message and $whatever->main_message($value).

Poof! Instant access to $whatever->main_message and $whatever->main_message($value).

And if you dont like that style accessor there is MooseX::FollowPBP for Perl Best Practices style accessors (like you have in your example), MooseX::SemiAffordanceAccessor (for foo/set_foo style) and MooseX::Accessors::ReadWritePrivate which pretty much handles everything else (so the docs seem to indicate, I haven't used it myself).

sub accountnumber {
   my ($self, $num) = @_;

   if (defined($num)) {
      $self->{account_num} = $num;
      return $self;
   } else {
      return $self->{account_num};
   }
}
[download]

use base qw(Class::Accessor);

__PACKAGE__->mk_accessors(qw(accountnumber));
[download]

It's interesting, this is how I write them too. But I noticed lodin's node, which contains an important but subtle difference; by doing this:

sub field {
    my $self = shift;
    $self->{field} = $_[0] if @_;
    ...
}
[download]

instead of this:

sub field {
    my ($self,$val) = @_;
    $self->{field} = $val if defined $val;
    ...
}
[download]

you don't run into issues where $self->field(undef) would silently return the old value without changing it, which isn't what you might expect. But because I've seen the second form elsewhere and it's technically better practice to assign @_ to variables I just stuck with it, but clearly the first way is better.

package Person;
    use Carp;
    our $AUTOLOAD;  # it's a package global

    my %fields = (
        name        => undef,
        age         => undef,
        peers       => undef,
    );

    sub new {
        my $class = shift;
        my $self  = {
            _permitted => \%fields,
            %fields,
        };
        bless $self, $class;
        return $self;
    }
[download]

sub AUTOLOAD {
        my $self = shift;
        my $type = ref($self)
                    or croak "$self is not an object";

        my $name = $AUTOLOAD;
        $name =~ s/.*://;   # strip fully-qualified portion

        unless (exists $self->{_permitted}->{$name} ) {
            croak "Can't access `$name' field in class $type";
        }

        if (@_) {
            return $self->{$name} = shift;
        } else {
            return $self->{$name};
        }
    }
[download]

Honestly, use of AUTOLOAD for this kind of stuff is just really a bad idea. You will outgrow this solution all too quickly, not to mention the fact that your code is broken once you introduce inheritance since you have no mechanism to inherit the fields. Sure that problem is solve-able but not without a bunch of tedious plumbing as well. It should also be noted that AUTOLOAD introduces something like a 400% performance penalty over normal method calls (which only gets bigger the more complex your AUTOLOAD gets).

-stvn

It should also be noted that AUTOLOAD introduces something like a 400% performance penalty over normal method calls

That penalty can be avoided for every but the first call to the autoloaded setter/getter function, if the AUTOLOAD block generates a subroutine living in a typeglob, just as AutoLoader does:

sub AUTOLOAD {
    my $self = shift;
    my $type = ref($self)
        or croak "$self is not an object";

    my $name = $AUTOLOAD;
    $name =~ s/.*://;   # strip fully-qualified portion

    unless (exists $self->{_permitted}->{$name} ) {
        croak "Can't access `$name' field in class $type";
    }
    my $sub = sub {
        my ($self,$value) = @_;
        $self->{$name} = $value if defined $value;
        $self->{$name};
    };
    {
        no strict 'refs';
        *{$name} = $sub;
    }
    goto $sub;
}
[download]

Each subsequent call to the method accesses the sub normally, i.e. through typeglob lookup.

not to mention the fact that your code is broken once you introduce inheritance since you have no mechanism to inherit the fields. Sure that problem is solve-able but not without a bunch of tedious plumbing as well.

That plumbing amounts to writing a proper import() subroutine which calls AUTOLOAD for the inherited fields and exports them to the inheriting class. But then, you're right, why reinvent the wheel (there are reasons, though) if there are plenty modules out there which handle that. There's Moose, classes, Class::Accessor, ...

The only good reason to use AUTOLOAD is when you already know you need to use it. It has a magic-from-afar type behavior that can be weird.
Danny.

I second stvn.

Since you know which fields are permitted when the class compiles you can generate them and get rid of AUTOLOAD. AUTOLOAD is really only needed when you do not know which methods the class will need to handle.

my @fields = qw/
  name
  age
  peers
/;

for my $name (@fields) {
  my $code = sub {
    my $self = shift;
    $self->{$name} = $_[0] if @_;
    return $self->{$name};
  };

  no strict 'refs';
  *$name = $code;
}
[download]

Now your class acts exactly like it would have acted if you manually wrote the methods, and you pay no run-time penalties.

Note how simple the logic of the code is compared to AUTOLOAD. And the AUTOLOAD implementation will get more complicated still. Consider what happens when you

• do $obj->can('age'),
• refactor and create a superclass that also uses AUTOLOAD, or
• use multiple inheritance where another class also uses AUTOLOAD.
• (Or forget to do return if $name eq 'DESTROY';.)
A proper implementation of AUTOLOAD requires an awful lot of thinking, and still it does not buy you anything, rather the opposite, if you already know the method names.

lodin