Re: greping big numbers


Perl: the Markov chain saw
	PerlMonks

Re: greping big numbers

by samtregar (Abbot)

on Mar 22, 2009 at 22:25 UTC ( [id://752449]=note: print w/replies, xml )

Need Help??

in reply to greping big numbers

I would use Bit::Vector for this. You'll need about 125MB of free memory, but that's easy to come by these days. Should work fine for overlapping ranges and runs very fast on my system:

use Bit::Vector;
use strict;
use warnings;

my $vector = Bit::Vector->new(1_000_000_000);
$vector->Fill();

my @ranges = ([39887, 399900],
              [23,    900],
              [8000,  10000],
              [50000, 1000500]);

$vector->Interval_Empty($_->[0] - 1, $_->[1] - 1) for @ranges;

my $start = 0;
while ($start < $vector->Size()
       and my ($min, $max) = $vector->Interval_Scan_inc($start))
{
    print(($min+1), "-", ($max+1), "\n");
    $start = $max + 2;
}
[download]

Prints:

$ perl bits.pl 
1-22
901-7999
10001-39886
1000501-1000000000
[download]

You might also look at Bit::Vector's to_Enum() and from_Enum() method, which do IO using ranges of indexes but it in a slightly different format from yours.

-sam