while (<HANDLE>) {
  next if 1..21;
  ... rest of processing here ...
}
[download]

-- Randal L. Schwartz, Perl hacker

That one is a weird one to get your head around... I never think of it. It is very cool, though. Of course, you could always do...

while (<HANDLE>) {
    last unless 1..21;
}
... rest of processing here ...
[download]

to prevent that check running for the following lines, but that's just downright ANAL :)
                - Ant

last unless 1..21;

Won't this do the opposite of what was intended and skip all but the first 21 lines of the file?

Any reason you wouldn't use:

<HANDLE> for 1..21;
...
[download]

   MeowChow                                   
               s aamecha.s a..a\u$&owag.print

You said:

Any reason you wouldn't use:

<HANDLE> for 1..21;
[download]

Yes. Try that with <ARGV> (aka <>) when there's only 15 lines in the files specified on the command line. After it hits EOF, it now starts reading unexpectedly from STDIN for the remaining 5 lines (after 1 undef for the eof), because the process starts over!

Moral: Always watch for an early EOF from a filehandle.

-- Randal L. Schwartz, Perl hacker

while (<FILE>) {
  unless (1 .. 21) {
    # process the line - which is in $_
  }
}
[download]

"Perl makes the fun jobs fun
and the boring jobs bearable" - me

Gee, if only computers could count!

for (my $i = 0; $i < 21; $i++) {
 <FILEHANDLE>;
}
# now read
[download]

or you could keep a count... next unless $i++ > 21;
                - Ant

--
my $chainsaw = 'Perl';

open (DATA, "<file.txt") or die "Can't open file $!\n";
my @DATA = <DATA>;
close (DATA);

foreach $rec (@DATA) {
    chomp $rec;
    ($var1, $var2, $var3, $var4) = split(/,/,$rec);
    $var1 =~ s/\s+$//g;
    $var1 =~ s/"//g;
    $var2 =~ s/\s+$//g;
    $var2 =~ s/"//g;
    $var3 =~ s/\s+$//g;
    $var3 =~ s/"//g;
    $var4 =~ s/\s+$//g;
    $var4 =~ s/"//g;
          $compHash{$var1} = $var2;
    $aliasHash{$var3} = $var1;
}
[download]

open (DATA, "<file.txt") or die "Can't open file $!\n";
<DATA> while $. < 21;
my @DATA = <DATA>;
close (DATA);
[download]

Nice use of an obscure variable (the obfuscator in me salutes you), but you'd better hope that the file is at least 22 lines long, or you'll be waiting quite a while for your data :-)

   MeowChow                                   
               s aamecha.s a..a\u$&owag.print

You are repeating quite a bit of code there :) Try this (partially tested)-

my $file = 'file.txt';
# open for input is default and now our die tells us which 
# file we were trying to open
open (DATA, $file) or die "Can't open $file $!\n";

# assuming you aren't using @DATA for something else later
# there is no need to slurp it all into memory now
while (<DATA>) {
  next unless $. > 21;
  chomp;
  my @temp=();
  foreach (split /,/){ 
    s/"//g;       # strip the quotes first if you want 
    s/\s+$//;     # to remove trailing whitespace 
    push @temp, $_;
  }

  $compHash{$temp[0]} = $temp[1];
  $aliasHash{$temp[2]} = $temp[3]; # you did mean $var4?
}
close (DATA);
[download]

I am sure it could be reduced further with a judicious use of map but I can't get my head around it this morning :(

Since you are parsing quoted CSV data you may want to look at Text::CSV which is a standard module or tilly's Text::xSV which is also available from CPAN.

--
my $chainsaw = 'Perl';

(undef,undef,undef,undef,$line) = <FILE>;
[download]

Something I always use for the xth line of a file....

(undef,undef,undef,undef,$line) = <FILE>;
[download]

At the expense of reading the entire file and tossing all but one of the lines. Ouch!

-- Randal L. Schwartz, Perl hacker

Isn't it more maintainable to write that as:

$line = (<FILE>)[4];
[download]

?

open MY_FILE, $filename;
seek MY_FILE, 21, 0;
while (<MY_FILE) {
... do reading schtuff here ...
}
[download]

That way, you go right to where you want to go. No silly while loops or anything like that.

That'd be 21 bytes, not 21 lines.

-- Randal L. Schwartz, Perl hacker

whoops. I'm a dunce! That'll teach me to think I can see something easy that 4 monks before me didn't.