http://qs321.pair.com?node_id=735427


in reply to Bug in substitution operator?

Just disambiguate the $1 with braces as well: ${1}: 
#!/usr/bin/perl
use strict;
use warnings;

my @lines = split /\n/, <<'END';
begin{verbatim}
hello all
end{verbatim}
END

s{((?:begin|end)){verbatim}}{${1}{whatever}} for @lines;
print "$_\n" for @lines;

__END__
begin{whatever}
hello all
end{whatever}

[download]

Replies are listed 'Best First'.
Re^2: Bug in substitution operator?
by polettix (Vicar) on Jan 10, 2009 at 20:53 UTC
    Hi rhesa, thanks for your answer. As a matter of fact, this is exactly what I put in my code to solve this problem in the first place.

    Anyway, the point in this post is not how work this situation around, but to understand if this is a bug or not, i.e. if this is something to work around.

    perl -ple'$_=reverse' <<<ti.xittelop@oivalf

    Io ho capito... ma tu che hai detto?
[reply]
      update: my example went the wrong way. This is the issue: 
      use strict;
my $v = 'x';
print qq"$v{a}";
__END__
xa

      [download]
      versus 
      use strict;
my $v = 'x';
print qq{$v{a}};
__END__
Global symbol "%v" requires explicit package name at -e line 3.

      [download]
      I think the following quote from perlop under "Gory details of parsing quoted constructs" sheds some light on this quirk:

      Note also that the interpolation code needs to make a decision on where the interpolated scalar ends. For instance, whether "a $b -> {c}" really means: 
         "a " . $b . " -> {c}";

      [download]
      or: 
        "a " . $b -> {c};

      [download]
      Most of the time, the longest possible text that does not include spaces between components and which contains matching braces or brackets. because the outcome may be determined by voting based on heuristic estimators, the result is not strictly predictable. Fortunately, it’s usually correct for ambiguous cases.

      I don't see this as a bug. Remember that the right-hand-side of s/// is just a double-quoted string, subject to the usual interpolation rules.

      The same disambiguation is needed in regular interpolated strings. Consider this snippet: 

      use strict;
my $var = "this";
print "$var{whatever}";
__END__
Global symbol "%var" requires explicit package name at -e line 3.

      [download]
      To fix the syntax error, and get the desired output, you do this: 
      use strict;
my $var = "this";
print "${var}{whatever}";
__END__
this{whatever}

      [download]
[reply]
[d/l]
[select]
        I get the same error in both examples:
        use strict;
my $v = 'x';
print qq"$v{a}";
__END__
Global symbol "%v" requires explicit package name at rhesa1.pl line 3.
Execution of rhesa1.pl aborted due to compilation errors.

        [download]
        I agree that the attention should be moved to double quotes, anyway. This gives the very same error as above:
        use strict;
my $v = 'x';
print qq{$v\{a\}};
__END__
Global symbol "%v" requires explicit package name at rhesa3.pl line 3.
Execution of rhesa3.pl aborted due to compilation errors.

        [download]
        while this doesn't:
        use strict;
my $v = 'x';
print "$v\{a\}";
__END__
x{a}

        [download]
        I'm not convinced that it'is an incarnation of the problem described in the documentation, anyway: in our case we have a different behaviour in the very same string when the double-quoted string is delimited with different characters, which is not what's discussed in the docs.

        perl -ple'$_=reverse' <<<ti.xittelop@oivalf

        Io ho capito... ma tu che hai detto?
[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom