I avoid FindBin since the it has problems. There are easy to use alternatives:

use Cwd qw( realpath );
$script_fqn = realpath($0);
[download]

use File::Basename qw( basename );
$script_fn = basename($0);
[download]

use Cwd            qw( realpath );
use File::Basename qw( dirname );
$script_dir_fqn = dirname(realpath($0));
[download]

Update: I originally use File::Spec::Functions's rel2abs, but it doesn't handle symlinks properly. I've updated the table to use Cwd's realpath which does, as per replies.

All of those mechanisms break if the script is being called by a symlink, and particularly so if nested symlinks are involved. You need to readlink($0) if (-l $0) first, and then check, and even then, it won't give you the same output as FindBin::RealBin.

Create the following directory structure in /var/tmp. Set up directories as follows (you'll need root for /usr/local/bin, so feel free to make the last step anywhere else in your path that you'd like):

cd /var/tmp
mkdir mydir
mkdir datadir
mkdir otherdir
cd otherdir
ln -s ../mydir symdir
[download]

Now take the following code and put it in /var/tmp/mydir/myname.pl:

#!/usr/bin/perl

use strict;
use warnings;

use FindBin;
use File::Basename qw( dirname );
use File::Spec::Functions qw( rel2abs );

my $name = $0;
$name = readlink($name) if(-l $name);

print "Finding a data path:\n\n";
print 'dirname($name):',dirname($name),"/../datadir\n";
print 'dirname(rel2abs($name)):',dirname(rel2abs($name)),"/../datadir\
+n";
print 'dirname($0):',dirname($0),"/../datadir\n";
print 'dirname(rel2abs($0)):',dirname(rel2abs($0)),"/../datadir\n";
print '$FindBin::RealBin:',$FindBin::RealBin,"/../datadir\n";
[download]

Symlink /var/tmp/symdir/myname.pl to /usr/local/bin/myname (or somewhere else on your path, if you can't or don't want to tamper with a system directory). Run 'myname'. You get:

Finding a data path:

dirname($name):/var/tmp/otherdir/symdir/../datadir
dirname(rel2abs($name)):/var/tmp/otherdir/symdir/../datadir
dirname($0):/usr/local/bin/../datadir
dirname(rel2abs($0)):/usr/local/bin/../datadir
$FindBin::RealBin:/var/tmp/mydir/../datadir
[download]

Only FindBin correctly points you to the correct data directory location.

Frankly, even without symlink forests, FindBin is more readable, though.

All of those mechanisms break if the script is being called by a symlink, and particularly so if nested symlinks are involved. You need to readlink($0) if (-l $0) first,

Agreed.

Only FindBin correctly points you to the correct data directory location.

That's wrong.

/var/tmp/otherdir/symdir/../datadir
[download]

is the same directory as

/var/tmp/mydir/../datadir
[download]

so you demonstrated that working with readlinked $0 works.

even then, it won't give you the same output as FindBin::RealBin.

Doesn't matter.

FindBin is more readable, though.

What good is readable if it doesn't work as well. And I don't see how dirname($script_qn) is less readable than $FindBin::RealBin.

rel2abs doesn't have a problem with symlinks as No checks against the filesystem are made. , it simply uses Cwd::cwd() as the base (rel2abs($path,$base)).

That it doesn't check against the file system is the problem. The goal is to find a file or directory relative to the placement of the script, not relative to the placement of a shortcut to the script.

I have read that $0 also gives the path on some operating systems. Maybe it was in an outdated book ",

I'm so adjective, I verb nouns!

chomp; # nom nom nom

Yes it does include the path. I use the following to get just the base file name of the program:

use File::Basename;

my $MyName = (fileparse($0, '\..*'))[0];
[download]

use Cwd qw(realpath);
use File::Basename;

my ($BIN, $BINPATH);
BEGIN { $BIN = basename($0); $BINPATH = realpath($0) }
[download]

How can a module determine the location of itself, independently of the CWD, and independently of the location of the script that is using it.

Eg. if the module is ~/lib/Ingenious.pm, and the script using it is ~/apps/Handy/Process.pl, and the CWD is ~/data/stuff/, then how could Ingenious.pm best determine that it's in ~/lib/ ?

After a bit of head scratching, I cobbled together a generic enough "solution":

foreach (@INC)
{
    if (-f "$_/".__PACKAGE__.".pm")
    {
        $iAmHere = $_;
        last;
    }
}
[download]

It feels like a hack, but hey - I wrote it before I found PerlMonks, so now seems like a good time to ask whether there's a better way of doing it. Any thoughts?

use Cwd qw( realpath );

my $iAmHere = realpath( __FILE__ );
[download]

Take a look at %INC, it gives you the absolute path of the loaded module.

Other posters have given the canonical answers to this already, so I won't repeat them.

Just a word of caution: if you're using modules that put objects or CODE refs in the @INC array, i.e. potentially load code without reading from a file, either method will not work.

One such case are packaging modules such as PAR or ex::lib::zlib. So depending on how your module is used, the answer is: It's impossible to find its filename!

If you're going to write code that requires the location of the module file name, please think about it some more. It might not be the smartest way to solve your problem.

Cheers,
Steffen