Note that there is no method to obtain the filehandle from the "File::Temp" object. The object itself acts as a filehandle. Also, the object is configured such that it stringifies to the name of the temporary file, and can be compared to a filename directly. The object isa "IO::Handle" and isa "IO::Seekable" so all those methods are available.

Update: I used Acme::ESP when I wrote the above. I assumed you wanted to write to the tempfile and read it in again later.

use File::Temp;
use strict;
my $fh = File::Temp->new(SUFFIX=>'.txt') or die "File::Temp: $!\n";

# $fh is a file handle.  You can use it like this
print $fh "This is a test\n";

# or as an object
$fh->print("This is a only a test\n");
$fh->write("Testing 1,2,3\n");

# You can rewind and read it
seek $fh, 0, 0 or die "Seek $fh failed: $!\n";
while (<$fh>) {
  print "Guess what I read: $_";
}

# You can also use it as a filename to open it
open ANOTHERFH, "<", $fh or die "Cannot open $fh: $!\n";
while (<ANOTHERFH>) {
  print "ANOTHERFH: $_";
}
[download]

use strict;
use warnings;
use Data::Dumper;
use File::Temp;

my $fh = File::Temp->new(SUFFIX=>'.txt');
my $tempfile = $fh->filename;

print "fh      =$fh\n";
print "tempfile=$tempfile\n";

print 'fh       ', Dumper($fh);
print 'tempfile ', Dumper($tempfile);

__END__
fh      =/tmp/JskZI6GUgu.txt
tempfile=/tmp/JskZI6GUgu.txt
fh       $VAR1 = bless( \*{'File::Temp::$fh'}, 'File::Temp' );
tempfile $VAR1 = '/tmp/JskZI6GUgu.txt';
[download]

which is why $fh is opened for writing only

The filehandle is opened read-write.