Your immediate problem has been resolved. However there are a few other things you ought to consider:

unless (open(INFILE, $csv_filename)){
    print "Cannot open file \"$csv_filename\"\n";
    exit;
  }
[download]

is better written:

open my $inFile, '<', $csv_filename or die qq{Cannot open file "$csv_f
+ilename"\n};
[download]

which declares a lexical file handle, uses the safer three parameter version of open and uses the more idiomatic die for error handling.

foreach $line (<INFILE>) {
[download]

slurps the file and introduces a variable that, in a subtle fashion, isn't the one you think it is (see Foreach Loops and note that the variable is aliased). You would be better to use a while loop:

while (defined (my $line = <$inFile>)) {
[download]

The close INFILE should be outside the loop. It didn't matter for the foreach loop because you were slurping the file, but it will cause trouble for the while loop version.

        my @field = $csv->fields;
        my $count = 0;
        for my $column (@field) {
            ++$count;
            $d_array[$line_number][$count] = $column;
        }
[download]

is better written:

        $d_array[$line_number] = [$csv->fields ()];
[download]

Update: oh, and if you use $. instead of $line_number you get the actual file line number. Note though that $d_array[0] at least will be undef using either your current line counting technique or the $. technique.

my variables are defined strictly lexical. That means d_array is only defined and known after line 23, but not in line 10 where you already use it. Move the line 'my d_array;' before the subroutine definition and it should work. Even better would be to give the array to the subroutine as a parameter:

sub printRow{
  #input the row number
  print Dumper(@_);
}
# and later:
&printRow(@d_array);
[download]

By the way, your for-loop can be replaced by this simple line:

$d_array[$line_number]= [@field];
[download]

Thanks all.
Moving the definition worked.
The textbook I have says it doesn't matter where you define a variable. Time to get a better text book!
Thanks again

Depends on how you define it. The text is talking about global variables, which are available to code outside their containing block:

{ 
    $i = 3;
}

print "$i\n";
[download]

Prints 3. Compare with:

{ 
    my $i = 3;
}

print "$i\n";
[download]

Without strict, this prints only a newline. This code declares a lexically scoped $i, which only persists through the end of its enclosing block. One of the best things about strict/warnings is that perl will complain about this kind of thing, possibly saving you a bunch of time hunting down a confusing error in a large program.

   push @d_array, [ $csv->fields() ];
[download]

@d_array = map { $csv->parse($_) ? [ $csv->fields() ] 
                                 : warn($csv->error_input), () }
                <INFILE>;
[download]

I also suggest you pass a reference to printrow():

sub printRow{
  my ($aref) = @_;

  print Dumper($aref);
}
## call like this ..

printRow(\@d_array); # using & is deprecated
[download]

 $d_array[$line_number]=[];
[download]

Sorry, my bad. Been up all night trying to fix this thing and getting a little groggy. The error is this:



Global symbol "@d_array" requires explicit package name at ./subtest.p
+l line 10.
Execution of ./subtest.pl aborted due to compilation errors.
[download]

As you have it, the scope of the my @d_array does not include your sub printRow. Move the sub declaration to the end, or move the my declaration to the top.

Also, you probably want to be passing array refereces to Dumper (or at least be aware of the different output in the two cases):

use strict;
use warnings;
use Data::Dumper;

my @ar = qw( a b c );
print Dumper(\@ar);
print Dumper(@ar);
__END__
$VAR1 = [
          'a',
          'b',
          'c'
        ];
$VAR1 = 'a';
$VAR2 = 'b';
$VAR3 = 'c';
[download]

Chiming in a bit late after a YAPC::EU visit.

Note that parsing CSV like this is not perfectly safe. Using $csv->getline () is not only much safer, but also solves your question instantly:

open my $fh, "<", $csv_filename or die "Cannot open file \"$csv_filena
+me\": $!\n";

while (my $row = $csv->getline ($fh)) {
    $d_array[++$line_number] = $row;
    # or even nicer
    # push @d_array, $row;
    }
$csv->eof or $csv->error_diag ();
close $fh or die "Cannot open file \"$csv_filename\": $!\n";
[download]

See how elegant and short?